Ton code est correct, félicitations ! Le problème c’est en effet l’impossibilité de calculer quelquechose dés les premiers chandeliers car on a des valeurs nulles, donc il faut ajouter une condition sur le barindex, en général j’utilise la valeur la plus élevé des périodes de calcul, ici “lengthMA”, soit attendre 34 chandeliers avant de lancer des calculs:

// @author LazyBear

// Paramètres en entrée
lengthMA = 34
lengthSignal = 9

//src=hlc3
src = (high + low + close)/3
//

if barindex>lengthMA then 
//calc_smma(src, len) =>
//smma=na(smma[1]) ? sma(src, len) : (smma[1] * (len - 1) + src) / len
//smma
//hi=calc_smma(high, lengthMA)
hi = (hi[1] * (lengthMA - 1) + high) / lengthMA
//lo=calc_smma(low, lengthMA)
lo = (lo[1] * (lengthMA - 1) + low) / lengthMA

//calc_zlema(src, length) =>
//ema1=ema(src, length)
//ema2=ema(ema1, length)
//d=ema1-ema2
//ema1+d
//mi=calc_zlema(src, lengthMA)
ema1 = ExponentialAverage[lengthMA](src)
ema2 = ExponentialAverage[lengthMA](ema1)
d = ema1 - ema2
mi = ema1 + d

//md = (mi>hi) ? (mi-hi) : (mi<lo) ? (mi-lo) : 0
if mi > hi then
md = mi - hi
elsif mi < lo then
md = mi - lo
else
md = 0
endIf

//sb = sma(md, lengthSignal)
//sh = md - sb
sb = Average[lengthSignal](md)
sh = md - sb

//mdc = src>mi ? src>hi ? lime : green : src<lo ? red : orange
if src > mi then
if src > hi then
//mdc = lime
mdcR = 0
mdcG = 255
mdcB = 0
else
//mdc = green
mdcR = 0
mdcG = 128
mdcB = 0
endIf
elsIf src < lo then
//mdc = red
mdcR = 255
mdcG = 0
mdcB = 0
else
//mdc = orange
mdcR = 255
mdcG = 165
mdcB = 0
endIf

//plot(0, color=gray, linewidth=1, title="MidLine")
//plot(md, color=mdc, linewidth=2, title="ImpulseMACD", style=histogram)
//plot(sh, color=blue, linewidth=2, title="ImpulseHisto", style=histogram)
//plot(sb, color=maroon, linewidth=2, title="ImpulseMACDCDSignal")

//ebc=input(false, title="Enable bar colors")
//barcolor(ebc?mdc:na)
endif 

return 0 as "MidLine", md COLOURED(mdcR, mdcG, mdcB) style(histogram,1) as "ImpulseMACD", sh COLOURED("blue") style(histogram,2) as "ImpulseHisto", sb COLOURED("maroon") style(line,2) as "ImpulseMACDCDSignal"//, ema1, ema2