I ran this code since 7 Dec 2017 (as a test phase on demo account before going live with it) and so far it has delivered £959. Just over a month.
1 minute time frame with 2 mini contracts.

The main reason I add this is becuse may be someone can some changes or even test it yourself and use it as is.
I have other ones on the same basis where I added TS and MFE (also Sir. Nicolas’s code). These are still in testing phase though.

I have tested with various options/variables on various Indices and forex pairs over months.
Because of the variables this code can apply to any forex or Indice on any timeframe. Anything from 10sec to 4hour. You just have to find your own sweet spot that applies to you.

This code will check for 4 (in this case) consecutive bullish or bearish candlesticks.
After that the variables apply – Inverse trading and Cumulate orders.
In this case it will open position in the same direction as the candles/trend. (InverseTrading = 0) and will cumulate orders (CumulateOrder = 1)

//-------------------------------------------------------------------------
//PRC_TS multiple candlesticks | indicator
//01.03.2017
//Nicolas @ www.prorealcode.com
//Sharing ProRealTime knowledge

//This is not my code.
//Original code was written and published by Sir.Nicolas

//-------------------------------------------------------------------------
// Prevents the system from creating new orders to enter the market or increase position size before the specified time
noEntryBeforeTime = 070000 //UTC +2
timeEnterBefore = time >= noEntryBeforeTime

// Prevents the system from placing new orders to enter the market or increase position size after the specified time
noEntryAfterTime = 190000 //UTC +2
timeEnterAfter = time < noEntryAfterTime

// --- parameters
Size = 2 //position size
StopLoss = 40 //stoploss in points
TakeProfit = 20 //takeprofit in points
Xcandlesticks = 4 //consecutive bullish or bearish candlesticks to open a new position
InverseTrading = 0 //(0=false ; 1=true) trade in the same direction of the candlesticks pattern or not
CumulateOrder = 1 //(0=false ; 1=true) cumulate or not a new trade if the current candlestick is in the same trend as the pattern
// ------------

//detecting patterns
bearpattern = summation[Xcandlesticks](close<open)=Xcandlesticks
bullishpattern = summation[Xcandlesticks](close>open)=Xcandlesticks

//first order
if not onmarket and timeEnterBefore and timeEnterAfter then
if bearpattern then
if InverseTrading then
BUY Size CONTRACTS AT MARKET
else
SELLSHORT Size CONTRACT AT MARKET
endif
lastbar = barindex
lastpattern = -1
endif
if bullishpattern then
if InverseTrading then
SELLSHORT Size CONTRACT AT MARKET
else
BUY Size CONTRACTS AT MARKET
endif
lastbar = barindex
lastpattern = 1
endif
endif

//cumulate order when a new pattern occurred
if onmarket and timeEnterBefore and timeEnterAfter and not CumulateOrder and barindex-lastbar>=Xcandlesticks then
if bearpattern then
if InverseTrading then
BUY Size CONTRACTS AT MARKET
else
SELLSHORT Size CONTRACT AT MARKET
endif
lastbar = barindex
endif
if bullishpattern then
if InverseTrading then
SELLSHORT Size CONTRACT AT MARKET
else
BUY Size CONTRACTS AT MARKET
endif
lastbar = barindex
endif
endif

//cumulate order when a new consecutive candletick happen right after the pattern occurred
if onmarket and timeEnterBefore and timeEnterAfter and CumulateOrder and barindex-lastbar=1 then
if longonmarket then
if (close>open and lastpattern=1) or (close<open and lastpattern=-1) then
BUY Size CONTRACTS AT MARKET
lastbar = barindex
endif
endif
if shortonmarket then
if (close>open and lastpattern=1) or (close<open and lastpattern=-1) then
SELLSHORT Size CONTRACT AT MARKET
lastbar = barindex
endif
endif
endif

SET STOP PLOSS StopLoss
SET TARGET PPROFIT TakeProfit

//END

May be someone can some changes or even test it yourself and use it as is.

I have tested the various options/variables on various Indices and forex pairs over months.
Because of the variables this code can apply to any forex or Indice on any timeframe. Anything from 10sec to 4hour. You just have to find your own sweet sport that applies to you.

This code will check for 4 (in this case) consecutive bullish or bearish candlesticks.
After that the variables apply – Inverse trading and Cumulate orders.
In this case it will open position in the same direction as the candles/trend. (InverseTrading = 0) and will cumulate orders (CumulateOrder = 1)

DAX-1min-multiple-candle-001.jpg DAX-1min-multiple-candle-002.jpg DAX-1min-multiple-candle.xls