como ajustar el horario en un indicador por cambio de Horario de Verano Europeo

Hola. Aquí tienes un ejemplo:

// === PARÁMETROS DE USUARIO ===
StartHour = 80000
EndHour = 180000
ajustarHorarioVerano = 0 // poner en 1 si quieres añadir +1h
LookbackPeriod = 10
PointsDistance = 5
cooldownVelas = LookbackPeriod // espera tras ruptura simulada

// === AJUSTES HORARIOS ===
ajuste = 0
IF ajustarHorarioVerano THEN
ajuste = 10000
ENDIF
horaInicio = StartHour + ajuste
horaFin = EndHour + ajuste

// === VARIABLES DE CONTROL ===
ONCE enEspera = 0
ONCE contadorEspera = 0
ONCE nivelSuperior = 0
ONCE nivelInferior = 0
ONCE ultimaRuptura = 0

// === CÁLCULO DEL RANGO ===
enHorario = Time >= horaInicio AND Time <= horaFin
suficientesVelas = intradaybarindex >= LookbackPeriod * 2

IF enHorario AND suficientesVelas AND enEspera = 0 THEN
maxRango = HIGHEST[LookbackPeriod](high)
minRango = LOWEST[LookbackPeriod](low)
    
nivelSuperior = maxRango + PointsDistance * PointSize
nivelInferior = minRango - PointsDistance * PointSize
    
// Simulación de ruptura
IF high > nivelSuperior[1] THEN
enEspera = 1
contadorEspera = cooldownVelas
ultimaRuptura = 1
precioEntradaLargo=max(open,nivelSuperior[1])
drawarrowup(barindex,low)coloured("green")
drawpoint(barindex,precioEntradaLargo,2)coloured("blue")
ELSIF low < nivelInferior[1] THEN
enEspera = 1
contadorEspera = cooldownVelas
ultimaRuptura = -1
precioEntradaCorto=min(open,nivelInferior[1])
drawarrowdown(barindex,high)coloured("red")
drawpoint(barindex,precioEntradaCorto,2)coloured("blue")
ENDIF
ENDIF

// === CONTROL DE TIEMPO DE ESPERA ===
IF enEspera = 1 THEN
contadorEspera = contadorEspera - 1
IF contadorEspera <= 0 THEN
enEspera = 0
ultimaRuptura = 0
ENDIF
ENDIF

// === VISUALIZACIÓN ===
if enHorario=0 then
backgroundcolor("grey",45)
endif
//-------------------------------------//
return nivelSuperior as "SUP"coloured("green"),nivelInferior as "INF"coloured("Red")