Colorazione di candele e barre all’incrocio di 2 medie mobili adattive

Viewing 3 posts - 1 through 3 (of 3 total)

Author

Posts

11/27/2020 at 7:57 AM #151845 quote

Hans63

Participant

Average

E’ possibile avere un codice per un indicatore che mi colori le barre quando si incrociano 2 medie mobili adattive?

Rispetto a 2 medie mobili tradizionali (semplici o esponenziali) funzionano molto meglio

Grazie

2-MEDIE-MOBILI-ADATTIVE.png

11/27/2020 at 8:16 AM #151851 quote

Hans63

Participant

Average

L’ideale sarebbe poter colorare anche di un colore neutro, quando la candela chiude sopra/sotto la media più lunga e/o sopra/sotto la media più corta

11/27/2020 at 10:55 AM #151889 quote

robertogozzi

Moderator

Legend

Eccolo (i colori puoi variarli come vuoi, vedi tabella http://cloford.com/resources/colours/500col.htm):

//////////////////////////////////////////////////////////////////////
//                         fast KAMA
////////////////////////////////////////////////////////////////////////
//    parameters:
ONCE Period1             = 12                               //12
ONCE FastPeriod1         = 2                                //2
ONCE SlowPeriod1         = 28                               //28
Fastest1   = 2 / (FastPeriod1 + 1)
Slowest1   = 2 / (SlowPeriod1 + 1)
if barindex < (Period1 + 1) then
Kama1   = close
else
Num1    = abs(close-close[Period1])
Den1    = summation[Period1](abs(close - close[1]))
ER1     = Num1 / Den1
Alpha1  = SQUARE(ER1 *(Fastest1 - Slowest1) + Slowest1)
Kama1   = (Alpha1 * Close) + ((1 - Alpha1) * Kama1[1])
endif
////////////////////////////////////////////////////////////////////////
//                         slow KAMA
////////////////////////////////////////////////////////////////////////
//    parameters:
ONCE Period2             = 50                               //50
ONCE FastPeriod2         = 2                                //2
ONCE SlowPeriod2         = 30                               //30
Fastest2   = 2 / (FastPeriod2 + 1)
Slowest2   = 2 / (SlowPeriod2 + 1)
if barindex < (Period2 + 1) then
Kama2   = close
else
Num2    = abs(close-close[Period2])
Den2    = summation[Period2](abs(close - close[1]))
ER2     = Num2 / Den2
Alpha2  = SQUARE(ER2 *(Fastest2 - Slowest2) + Slowest2)
Kama2   = (Alpha2 * Close) + ((1 - Alpha2) * Kama2[1])
endif
////////////////////////////////////////////////////////////////////////
x  = Kama1 CROSSES OVER  Kama2
x1 = (Kama1 > Kama2) AND (close > Kama1)
y = Kama1 CROSSES UNDER Kama2
y1 = (Kama1 < Kama2) AND (close < Kama1)
//
IF x THEN
DRAWCANDLE(open,high,low,close) COLOURED(0,192,0,255) BORDERCOLOR(238,118,33,255)  //VERDE  (incrocio rialzista)
ELSIF y THEN
DRAWCANDLE(open,high,low,close) COLOURED(205,0,0,255)  BORDERCOLOR(238,238,0,255)   //ROSSO  (incrocio ribassista)
ELSIF x1 THEN
DRAWCANDLE(open,high,low,close) COLOURED(238,232,170,160) BORDERCOLOR(0,0,0,0)   //VERDE  tenue (PREZZO > media veloce)
ELSIF y1 THEN
DRAWCANDLE(open,high,low,close) COLOURED(244,164,96,160)   BORDERCOLOR(0,0,0,0)   //ROSSO  tenue (PREZZO < media veloce)
ENDIF
RETURN

Hans63 thanked this post

Author

Posts

Viewing 3 posts - 1 through 3 (of 3 total)

You must be logged in to reply to this topic.

New

Stuck on this ProBuilder code?

Describe what this topic is trying to build, in plain English, and ProRealAI writes the ProRealTime™ indicator, screener or system for you.

Available in 7 languages

Try ProRealAI

Colorazione di candele e barre all’incrocio di 2 medie mobili adattive

ProBuilder: Indicatori & Strumenti Personalizzati

New Reply

Author

Hans63 @hans63 Participant

Summary

This topic contains 2 replies,
has 2 voices, and was last updated by robertogozzi
5 years, 10 months ago.

Topic Details

Forum:	ProBuilder: Indicatori & Strumenti Personalizzati
Language:	Italian
Started:	11/27/2020
Status:	Active
Attachments:	1 files