Here’s a strange thing: code specifies changing direction after a change in the Hull17. Running on the FTSE it works as expected but on the DAX there tends to be a lag, so orders happen not on the next candle but after 2 candles … much less good. Looking at the screen shot, the Hull17 turns up at 11:20 so it should close the short and open long next candle @ 13285 … but instead this happens a candle later @ 13296. Any thoughts ?

Here’s the code:

// Definition of code parameters
DEFPARAM CumulateOrders = False // Cumulating positions deactivated
// The system will cancel all pending orders and close all positions at 0:00. No new ones will be allowed until after the "FLATBEFORE" time.
DEFPARAM FLATBEFORE = 080000
// Cancel all pending orders and close all positions at the "FLATAFTER" time
DEFPARAM FLATAFTER = 163000
daysForbiddenEntry = OpenDayOfWeek = 6 OR OpenDayOfWeek = 0
 
Period=17
inner = 2*weightedaverage[round( Period/2)](typicalprice)-weightedaverage[Period](typicalprice)
 
hull = weightedaverage[round(sqrt(Period))](inner)
 
// Conditions to enter long positions
c1 = hull > hull[1]
c2 = hull < hull[1]
 
IF c1 AND not daysForbiddenEntry THEN
BUY 1 CONTRACT AT MARKET
SET STOP PLOSS 20
ENDIF
 
// Conditions to exit long positions
 
IF c2 THEN
SELL AT MARKET
ENDIF
 
// Conditions to enter short positions
 
IF c2 AND not daysForbiddenEntry THEN
SELLSHORT 1 CONTRACT AT MARKET
SET STOP PLOSS 20
ENDIF
 
// Conditions to exit short positions
 
IF c1 THEN
EXITSHORT AT MARKET
ENDIF
//trailing stop function
trailingstart = 20 //trailing will start @trailinstart points profit
trailingstep = 12 //trailing step to move the "stoploss"
 
//reset the stoploss value
IF NOT ONMARKET THEN
newSL=0
ENDIF
 
//manage long positions
IF LONGONMARKET THEN
//first move (breakeven)
IF newSL=0 AND close-tradeprice(1)>=trailingstart*pipsize THEN
newSL = tradeprice(1)+trailingstep*pipsize
ENDIF
//next moves
IF newSL>0 AND close-newSL>=trailingstep*pipsize THEN
newSL = newSL+trailingstep*pipsize
ENDIF
ENDIF
 
//manage short positions
IF SHORTONMARKET THEN
//first move (breakeven)
IF newSL=0 AND tradeprice(1)-close>=trailingstart*pipsize THEN
newSL = tradeprice(1)-trailingstep*pipsize
ENDIF
//next moves
IF newSL>0 AND newSL-close>=trailingstep*pipsize THEN
newSL = newSL-trailingstep*pipsize
ENDIF
ENDIF
 
//stop order to exit the positions
IF newSL>0 THEN
SELL AT newSL STOP
EXITSHORT AT newSL STOP
ENDIF
//************************************************************************
 

DAX-2.5.jpg