Perché scrivi TradePrice(3)?

TradePrice(1)  dovrebbe, in teoria, essere la chiusura appena fatta di una posizione, in realtà credo che fino alla chiusura della barra non sia così, in quanto solo allora si saprà se l’ordine di uscita è andato a buon fine o no, quindi è il prezzo di ENTRATA.

TradePrice(2) dovrebbe essere, quando funzionerà correttamente, il prezzo di uscita dell’ultima posizione dell’operazione precedente.

TradePrice(3) dovrebbe essere, quando funzionerà correttamente, il prezzo di uscita della penultima posizione dell’operazione precedente.

Aggiungi alla fine tuo codice le seguenti righe per osservare che prezzi ti vengono indicati:

GraphOnPrice TradePrice(1) coloured(255,0,0,255) //Rosso
GraphOnPrice TradePrice(2) coloured(0,128,0,155) //Verde
GraphOnPrice TradePrice(2) coloured(0,0,255,255) //Blù

Se acquisti 3 contratti in un’unica volta puoi usare TradePrice(1), o solo TradePrice.

Se, invece, accumuli 3 posizioni la cosa si complica. Non puoi scegliere te  quale contratto chiudere, ma ProOrder usa la regola FIFO, chiudendo sempre quello aperto per primo (il più vecchio), penso che sia quello che vuoi. Però devi tenere conto che dopo la prima chiusura parziale, scalano tutti di una posizione, perché TRADEPRICE è il prezzo dell’ultima operazione, che sia un’apertura o una chiusura.

Non li vendi insieme, dal momento  che vuoi effettuare 3 uscite.

Comunque interessa più se li acquisti insieme oppure no.

Il tuo codice è un pò macchinoso e con alcune pecche logiche:

1. sellshort 3 CONTRACTS AT low[1]-1.4 limit usa un ordine LIMIT, ma non è detto che il prezzo corrente sia per forza minore del minimo precedente, per cui dovresti verificare i due prezzi e usare LIMIT o STOP secondo il caso (se usi un tipo errato il broker fa entrate a mercato, oppure può rifiutare l’ordine ed interrompere la strategia)
2. myprofit = open – 50 (come pure gli altri due calcoli) utilizzano OPEN, invece del prezzo corrente (CLOSE), ma se c’è stato un forte spike la candela potrebbe anche avere fatto più di 50 punti che in realtà si può trovare SOPRA il prezzo d’entrata ed avresti un profitto in negativo
3. quando usi valori numerici da usare in espressioni dove ci sono dei prezzi (come nel caso di 1.4), converti i numeri in prezzo moltiplicandoli per PIPSIZE, quindi è logicamente corretto scrivere low[1] – 1.4 * pipsize; con indici come il DAX può risultare ininfluente, ma se provi la stessa strategia su EUR/USD ottieni prezzi negativi (1.03 – 1.4)
4. la riga 10, if myprofit then, è sempre vera, perché contiene un prezzo (qualunque esso sia) ed è quindi SEMPRE <> 0, quindi ha un valore logico vero, per cui appena entra a mercato esce.

Macchinoso perché puoi acuistare 3 contratti insieme, invece di fare 3 acquisti separatamente (che in ogni caso vengono raggruppati, perché gli ordini NON vengono eseguiti all’istante, ma solo alla fine del codice, quindi ProOrder li aggrega).

Io ho provato a riscriverlo cercando di seguire quanto più possibile le tue impostazioni e adattando i parametri al DAX, 15 minuti, con 15K unità sul grafico:

ONCE c1      = 0
myResistenza = 1
c2           = 1
Orario       = 1
IF close CROSSES UNDER average[200,0](close) AND Not ShortOnMarket THEN
c1 = 1
ENDIF
//
if not shortonmarket and myResistenza and c1 and orario and c2 then
Entrata   = min(low,low[1]) - 20.0 * PipSize
mystop    = max(high,high[1])
myprofit  = max(open,close) - 30   * PipSize
myprofit2 = max(open,close) - 60   * PipSize
myprofit3 = max(open,close) - 180  * PipSize
IF close > Entrata THEN
sellshort 3 CONTRACTS AT Entrata stop
ELSIF close < Entrata THEN
sellshort 3 CONTRACTS AT Entrata limit
ENDIF
ENDIF
// Uscita in Stop
If ShortOnMarket AND close >= mystop THEN
exitshort AT MARKET
ENDIF
// Condizioni per uscire da posizioni short
IF ShortOnMarket THEN
c1 = 0
IF close <= myprofit3 THEN
ExitShort at Market
ELSIF close <= myprofit2 AND abs(CountOfPosition) = 2 THEN
ExitShort 1 contract at Market
ELSIF close <= myprofit AND abs(CountOfPosition) = 3 THEN
ExitShort 1 contract at Market
ENDIF
ENDIF