Bonjour,
Je débute complètement en codage et j’aimerai un peu d’aide.
J’aimerai un code qui permette de détecter les divergences sur l’indicateur TSI (je mets le code en bas de page pour info), et si possible que les divergences soient détectées dans les zones de sur achat et de sur vente (zone paramétrable, par exemple +25 et -25 et que l’on puisse les modifier). L’idéal serait aussi qu’un signal sous forme de flèche apparaisse sur les prix aussi pour indiquer qu’une divergence est détectée.
Merci d’avance si vous pouvez m’aider.
Vincent
—————————————————
Code de l’indicateur TSI :
a = (ExponentialAverage[7](ExponentialAverage[14](ROC[1](close))))
b = (ExponentialAverage[7](ExponentialAverage[14](ABS(ROC[1](close)))))
TSI = 100 * (a/b)
RETURN TSI as “True Strength Index”, 0
Rapidement on peut utiliser ce code assez simple pour détecter les divergences :
a = (ExponentialAverage[7](ExponentialAverage[14](ROC[1](close))))
b = (ExponentialAverage[7](ExponentialAverage[14](ABS(ROC[1](close)))))
TSI = 100 * (a/b)
filterperiod=5
overboughtzone=25
oversoldzone=-25
x = TSI
y=average[filterperiod](x)
// BEARISH DIVERGENCES CCI
if x>overboughtzone then
hi=max(hi,x)
hico=max(hico,max(high,high[1]))
endif
if x crosses under y then
sto2b=sto1b
sto1b=hi
hi=0
p3b=p1b
p2b=max(p1b,hico1)
p1b=max(highest[3](high),hico)
if p2b=p1b then
p2b=max(p3b,p4b)
endif
hico=0
hico1=0
endif
if x<y then
p4b=hico1
hico1=max(hico1,high)
endif
if p1b>p2b and sto1b<sto2b and x crosses under y and x<x[1] then
signB= -2
else
signB= 0
endif
// BULLISH DIVERGENCES CCI
if x<oversoldzone then
lo=min(lo,x)
lowco=min(lowco,min(low,low[1]))
endif
if x CROSSES OVER y then
sto2h=sto1h
sto1h=lo
lo=100
p3h=p1h
p2h=min(p1h,lowco1)
p1h=min(lowest[3](low),lowco)
if p2h=p1h then
p2h=min(p3h,p4h)
endif
lowco=100000
lowco1=100000
endif
if x>y then
p4h=lowco1
lowco1=min(lowco1,low)
endif
if p1h<p2h and sto1h > sto2h and x crosses over y and x>x[1] then
signH= 2
else
signH= 0
endif
////////////////////////////////////////////////
return signH as " div CCI H ", signB as " div CCI B " , 0 as " zero "
Les signaux de divergences baissières et haussières sont les 2/-2.
Eh ben dis donc un GRAND merci, c’est tout à fait ce que je recherchais… Bravo l’artiste !
Et sincèrement merci pour la réponse, le temps consacré et le résultat…
J’ai passé des heures à chercher quelque chose mais en vain. Du coup j’en profite, je suis aussi à la recherche d’un indicateur de range… ça aussi c’est introuvable !
En gros un indicateur capable de détecter au bout de X bougies que les prix sont neutralisés, en range et dans l’idéal un signal pour la sortie ou cassure de range, pour fonctionner de présence sur des UT courtes (en dessous du 15 minutes)… si vous avez ça en magasin je suis preneur.
Dans l’attente je vous souhaite un bon week-end et encore merci pour ce super service Nicolas.
Vincent
