MAKSIDE wrote:

the analysis of a candle of a higher timeframe is the way for the exit

Maybe if a position runs bad. For a trade in profit probably the trailingstop would be good enough.

But it could also be used to prevent taking a trade. At the moment I’am testing that with the doji.

I don’t like to have too many indicators. One for the trend has to be enough.

Hi,

this is an interesting project and I like the idea of candle patterns with few indicators.
I’ve had this idea of using Larry Williams “Smash Day Pattern”-strategy on lower Time Frames.
I think his idea is simply clever and may be useful.

I’ve started a little project on my own, for educational purpose, with code name “SmashBar, the Larry style”…yeah I know, the name is…ehum…silly 🙂
If it’s OK, I’ll put the code here (if I break any forum rules please remove the code). As I mentioned, I’m still learning so my code might be a bit clumsy and probably not at all coded as the “Smash Day Pattern”. But hey, learning by doing, right? 😉

I’ve got the idea from https://oxfordstrat.com/?s=smash and also found a topic here at prorealcode:
https://www.prorealcode.com/prorealtime-indicators/larry-williams-smash-days/

//SmashBar, the Larry style

defparam cumulateorders = false
defparam preloadbars    = 5000

once positionsize     = 1
once tradetype        = 2 // [1]long&short;[2]long;[3]short

//========= STRATEGY ===================================

//long
c10=low<lowest[2](low[1])
c11=close<low[1]
tradelong = c10 and c11

//short
c20=high>highest[2](high[1])
c21=close>high[1]
tradeshort = c20 and c21

//=======================================================
// entry
If (tradetype=1 or tradetype=2) and tradelong then
if not onmarket then
buy positionsize contract at market
endif
endif

if (tradetype=1 or tradetype=3) and tradeshort then
if not onmarket then
sellshort positionsize contract at market
endif
endif

//%trailing stop function
trailingPercent = .26 //org .26
stepPercent = .015  //org .014
if onmarket then
trailingstart = tradeprice(1)*(trailingpercent/100) //trailing will start @trailinstart points profit
trailingstep = tradeprice(1)*(stepPercent/100) //% step to move the stop
endif
 
//reset the stoploss value
IF NOT ONMARKET THEN
newSL=0
ENDIF
 
//manage long positions
IF LONGONMARKET THEN
//first move (breakeven)
IF newSL=0 AND close-tradeprice(1)>=trailingstart THEN
newSL = tradeprice(1)+trailingstep
ENDIF
//next moves
IF newSL>0 AND close-newSL>trailingstep THEN
newSL = newSL+trailingstep
ENDIF
ENDIF
 
//manage short positions
IF SHORTONMARKET THEN
//first move (breakeven)
IF newSL=0 AND tradeprice(1)-close>=trailingstart THEN
newSL = tradeprice(1)-trailingstep
ENDIF
//next moves
IF newSL>0 AND newSL-close>trailingstep THEN
newSL = newSL-trailingstep
ENDIF
ENDIF
 
//stop order to exit the positions
IF newSL>0 THEN
SELL AT newSL STOP
EXITSHORT AT newSL STOP
ENDIF