No entiendo muy bien, si quieres el cálculo del indicador SAR, aquí lo tienes:

// SAR - Parabolic SAR
//
// https://www.prorealcode.com/topic/parabolic-sar-code/page/2/#post-174049
//
//    Parameters:
//
SARinit  = 0.02
SARstep  = 0.02
SARlimit = 0.2
//
IF BARINDEX < 2 THEN
   parabolic = LOW
   islong    = 1
   af        = SARlimit
   hp        = HIGH
   lp        = LOW
ELSE
   IF islong THEN
      parabolic = parabolic + af * (hp - parabolic)
      parabolic = MIN(parabolic, LOW[1])
      parabolic = MIN(parabolic, LOW[2])
   ELSE
      parabolic = parabolic + af * (lp - parabolic)
      parabolic = MAX(parabolic, HIGH[1])
      parabolic = MAX(parabolic, HIGH[2])
   ENDIF
   reverse = 0
   IF islong THEN
      IF LOW < parabolic THEN
         islong    = 0
         reverse   = 1
         parabolic = hp
         lp        = LOW
         af        = SARinit
      ENDIF
   ELSE
      IF HIGH > parabolic THEN
         islong    = 1
         reverse   = 1
         parabolic = lp
         hp        = HIGH
         af        = SARinit
      ENDIF
   ENDIF
   IF NOT reverse THEN
      IF islong THEN
         IF HIGH > hp THEN
            hp = HIGH
            af = af + SARstep
            af = MIN (af,SARlimit)
         ENDIF
      ELSE
         IF LOW < lp THEN
            lp = LOW
            af = af + SARstep
            af = MIN (af,SARlimit)
         ENDIF
      ENDIF
   ENDIF
ENDIF
RETURN parabolic as "parabolic SAR"

si eso no es lo que desea, intente proporcionar más detalles.

No se puede anticipar, ¿cómo se puede saber de antemano dónde se ubicará el SAR en el futuro?

Si tiene alguna fórmula para calcular esto por adelantado, me complacería codificarla en un indicador.

Puedo mostrarte el punto, pero solo cuando cambia el SAR.