This is a Breakout system made for IG market [ Hong Kong HS50 Cash (HKD10 Mini)], Time Frame: 15 mins.

All components were found from PRT forum, the core idea was from Reiner DAX Breakout system and Nicolas trailing stop. Walk forward test was not 100% perfect, Monte Carlo simulation with latest 12-month back test record show HKD$10,000 for the initial capital is ok.

But unfortunally, my live test result was not same as back test, I can’t find what’s wrong with my limited knowledge, hope you guys can help and determine what mistake inside.

// Market: Hong Kong HS50 Cash (HKD10 Mini)
//Time Frame: 15 mins
//Remark: HSI night trade start from 2013-04-08, 17:00-23:00,
//amended from 2014-11-03, 17:15-23:45

// code-parameter
DEFPARAM FlatAfter = 234500  //234500

// window high/low calculation
ONCE StartTime = 90000//91500
ONCE EndTime = 93000//100000

// trading window
ONCE BuyTime = EndTime
ONCE SellTime = 234500  //234500

//Spread
Spread=6

//Money management
ONCE PositionSize = 1
ONCE Capital = 10000
ONCE Risk = 5
ONCE MaxD = 50 // Quit system if highestc close account balance drop over xx%
equity = Capital + StrategyProfit
maxrisk = round(equity*(Risk/100))

//Check system account balance
if equity<QuitLevel then
quit
endif
recordhighest = MAX(recordhighest,equity)
QuitLevel = recordhighest*((100-MaxD)/100)

//MA Filter
FMA=Average[80](close)
SMA=Average[200](close)

// calculate breakout box high/low and sl/tp
IF Time >= StartTime AND Time <= EndTime THEN
IF TIME = StartTime THEN
DailyHigh = High
DailyLow = Low
ENDIF
IF High > DailyHigh THEN
DailyHigh = High
ENDIF
IF Low < DailyLow THEN
DailyLow = Low
ENDIF

sl = min(110,(max(30,((DailyHigh - DailyLow)+Spread))))
tp = sl*4

PositionSize = min(10,(max(1,abs(round((maxrisk/sl)/PointValue)*pipsize))))

TradeCounterLong = 0
TradeCounterShort = 0
ENDIF

//Define the best trading day and time and avoid trading at lunch & teakbreak high spread period, please manual stop system on Hong Kong public hoilday.
//Long
LOK1=currentdayofweek=1 and ((time>=091500 and time<120000) or (time>=130000 and time<160000) or (time>=171500 and time<230000))
LOK2=currentdayofweek=2 and ((time>=091500 and time<120000) or (time>=130000 and time<160000) or (time>=171500 and time<230000))
LOK3=currentdayofweek=3 and ((time>=091500 and time<120000) or (time>=130000 and time<160000) or (time>=171500 and time<230000))
LOK5=currentdayofweek=5 and  ((time>=130000 and time<160000) or (time>=171500 and time<230000))

//Short
SOK1=currentdayofweek=1 and ((time>=091500 and time<120000) or (time>=130000 and time<160000) or (time>=171500 and time<230000))
SOK2=currentdayofweek=2 and  ((time>=130000 and time<160000) or (time>=171500 and time<230000))
SOK4=currentdayofweek=4 and ((time>=091500 and time<120000)  or (time>=171500 and time<230000))
SOK5=currentdayofweek=5 and  ((time>=091500 and time<120000) or (time>=130000 and time<160000) or (time>=171500 and time<230000))

// Position management
IF Time >= BuyTime AND Time <= SellTime THEN

//Long Entry
IF Not LONGONMARKET and (LOK1 or LOK2 or LOK3 or LOK5) and close>DailyHigh and FMA>SMA and TradeCounterLong=0 THEN
BUY PositionSize CONTRACT AT MARKET
TradeCounterLong = TradeCounterLong + 1
ENDIF

//Short Entry
IF Not SHORTONMARKET and (SOK1 OR SOK2 OR SOK4 OR SOK5) and close<DailyLow and FMA<SMA AND TradeCounterShort=0 THEN
SELLSHORT PositionSize CONTRACT AT MARKET
TradeCounterShort = TradeCounterShort + 1
ENDIF

// trailing stop function
ONCE trailingStepLong = 0.08// in %
ONCE trailingStepShort = 0.08 // in %
trailingStartLongInPoints = max(30,(TP/5))
trailingStartShortInPoints = max(30,(TP/5))
trailingStepLongInPoints = max(10,(tradeprice(1) * trailingStepLong / 100))
trailingStepShortInPoints = max(10,(tradeprice(1) * trailingStepShort / 100))

// reset the stoploss value
IF NOT ONMARKET THEN
newSL = 0
ENDIF

// manage long positions
IF LONGONMARKET THEN
// first move (breakeven)
IF newSL = 0 AND close - tradeprice(1) >= trailingStartLongInPoints * pipsize THEN
newSL = tradeprice(1) + trailingStepLongInPoints * pipsize
ENDIF
// next moves
IF newSL > 0 AND close - newSL >= trailingStepLongInPoints * pipsize THEN
newSL = newSL + trailingStepLongInPoints * pipsize
ENDIF
ENDIF

// manage short positions
IF SHORTONMARKET THEN
// first move (breakeven)
IF newSL = 0 AND tradeprice(1) - close >= trailingStartShortInPoints * pipsize THEN
newSL = tradeprice(1) - trailingStepShortInPoints * pipsize
ENDIF
// next moves
IF newSL > 0 AND newSL - close >= trailingStepShortInPoints * pipsize THEN
newSL = newSL - trailingStepShortInPoints * pipsize
ENDIF
ENDIF

// stop order to exit the positions
IF newSL > 0 THEN
SELL AT newSL STOP
EXITSHORT AT newSL STOP
ENDIF

// close positions
IF Time = SellTime THEN
IF LONGONMARKET THEN
SELL AT MARKET
ENDIF
IF SHORTONMARKET AND Time = SellTime THEN
EXITSHORT AT MARKET
ENDIF
ENDIF

// stops and targets
SET STOP LOSS sl
SET TARGET PROFIT tp

ENDIF

圖片2.png 圖片1.png MB-result.png