Yes, you have to.

Yes, that’s correct, but you’ll have to replace CLOSE also at lines 44 (X1) and 56 (X2).

You have to keep CLOSE, instead, after line 68 when it deals with minimum distance required by the broker, which must ALWAYS be computed from current price (CLOSE).

Sorry guys, I had to change the above code:

• I had forgotten to replace TradePrice with PositionPrice in some lines
• I commented out line 34 and all references to PositionCount and added line 35 to use PositionPrice, instead, because it is most reliable in telling us there’s been a change.

I am also attaching the ITF file.

//------------------------------------------------------------------------------------------------------------------------------------------------
ONCE UseCLOSE = 1                                 //1=use CLOSE,  0=use High/Low
srcH = close                                      //defaults to CLOSE
srcL = close                                      //defaults to CLOSE
IF UseCLOSE = 0 THEN
   srcH = high
   srcL = low
ENDIF
DirectionSwitch = (LongOnMarket AND ShortOnMarket[1]) OR (LongOnMarket[1] AND ShortOnMarket)  //True when there's been a change in the direction (likely to be due to a Stop & Reverse)
IF Not OnMarket OR DirectionSwitch THEN
   //
   // when NOT OnMarket or thare's been a change in direction, reset values to their default settings
   //
   TrailStart    = 30          //30     Start trailing profits from this point
   BasePerCent   = 0.200       //20.0%  Profit percentage to keep when setting BerakEven
   StepSize      = 10          //10     Pip chunks to increase Percentage
   PerCentInc    = 0.100       //10.0%  PerCent increment after each StepSize chunk
   RoundTO       = -0.5        //-0.5   rounds always to Lower integer,   +0.4 rounds always to Higher integer,     0 defaults PRT behaviour
   PriceDistance = 7 * pipsize //7      minimun distance from current price
   y1            = 0           //reset to 0
   y2            = 0           //reset to 0
   ProfitPerCent = BasePerCent //reset to desired default value
   //PositionCount = 0
   SellPrice     = 0
   ExitPrice     = 9999999
ELSE
   //------------------------------------------------------
   // --- Update Stop Loss after accumulating new positions
   //------------------------------------------------------
   //PositionCount = max(PositionCount,abs(CountOfPosition))
   //
   // update Stop Loss only when PositionPrice has changed (actually when increased, we don't move it if there's been some positions exited)
   //
   //IF PositionCount <> PositionCount[1] AND (ExitPrice + SellPrice)<>9999999 THEN //go on only if Trailing Stop had already started trailing
   IF PositionPrice <> PositionPrice[1] AND (ExitPrice + SellPrice) <> 9999999 THEN //go on only if Trailing Stop had already started trailing
      IF LongOnMarket THEN
         q1         = PositionPrice + ((srcH - PositionPrice) * ProfitPerCent)      //calculate new SL
         SellPriceX = max(max(SellPriceX,SellPrice),q1)
         SellPrice  = max(max(SellPriceX,SellPrice),PositionPrice + (y1 * pipsize)) //set exit price to whatever grants greater profits, comopared to the previous one
      ELSIF ShortOnMarket THEN
         r1         = ((PositionPrice - srcL) * ProfitPerCent)                      //calculate new SL
         ExitPriceX = min(min(ExitPriceX,ExitPrice),r1)
         ExitPrice  = min(min(ExitPriceX,ExitPrice),PositionPrice - (y2 * pipsize)) //set exit price to whatever grants greater profits, comopared to the previous one
      ENDIF
   ENDIF
// --- Update END
ENDIF
//
IF LongOnMarket AND srcH > (PositionPrice + (y1 * pipsize)) THEN                              //LONG positions
   //
   // compute the value of the Percentage of profits, if any, to lock in for LONG trades
   //
   x1 = (srcH - PositionPrice) / pipsize                                     //convert price to pips
   IF x1 >= TrailStart THEN                                                //    go ahead only if N+ pips
      Diff1         = abs(TrailStart - x1)                                 //difference from current profit and TrailStart
      Chunks1       = max(0,round((Diff1 / StepSize) + RoundTO))           //number of STEPSIZE chunks
      ProfitPerCent = BasePerCent + (BasePerCent * (Chunks1 * PerCentInc)) //compute new size of ProfitPerCent
      ProfitPerCent = max(ProfitPerCent[1],min(100,ProfitPerCent))         //make sure ProfitPerCent doess not exceed 100%
      y1 = max(x1 * ProfitPerCent, y1)                                     //y1 = % of max profit
   ENDIF
ELSIF ShortOnMarket AND srcL < (PositionPrice - (y2 * pipsize)) THEN                             //SHORT positions
   //
   // compute the value of the Percentage of profits, if any, to lock in for SHORT trades
   //
   x2 = (PositionPrice - srcL) / pipsize                                     //convert price to pips
   IF x2 >= TrailStart THEN                                                //      go ahead only if N+ pips
      Diff2         = abs(TrailStart - x2)                                 //difference from current profit and TrailStart
      Chunks2       = max(0,round((Diff2 / StepSize) + RoundTO))           //number of STEPSIZE chunks
      ProfitPerCent = BasePerCent + (BasePerCent * (Chunks2 * PerCentInc)) //compute new size of ProfitPerCent
      ProfitPerCent = max(ProfitPerCent[1],min(100,ProfitPerCent))         //make sure ProfitPerCent doess not exceed 100%
      y2 = max(x2 * ProfitPerCent, y2)                                     //y2 = % of max profit
   ENDIF
ENDIF
//------------------------------------------------------------------------------
//                    manage actual Exit, if needed
//------------------------------------------------------------------------------
IF y1 THEN                                                                 //Place pending STOP order when y1 > 0   (LONG positions)
   SellPrice = max(SellPrice,PositionPrice + (y1 * pipsize))                  //convert pips to price
   //
   // check the minimun distance between ExitPrice and current price
   //
   IF abs(close - SellPrice) > PriceDistance THEN
      //
      // place either a LIMIT or STOP pending order according to current price positioning
      //
      IF close >= SellPrice THEN
         SELL AT SellPrice STOP
      ELSE
         SELL AT SellPrice LIMIT
      ENDIF
   ELSE
      //
      //sell AT MARKET when EXITPRICE does not meet the broker's minimun distance from current price
      //
      SELL AT Market
   ENDIF
ENDIF
IF y2 THEN                                                                 //Place pending STOP order when y2 > 0   (SHORT positions)
   ExitPrice = min(ExitPrice,PositionPrice - (y2 * pipsize))                  //convert pips to price
   //
   // check the minimun distance between ExitPrice and current price
   //
   IF abs(close - ExitPrice) > PriceDistance THEN
      //
      // place either a LIMIT or STOP pending order according to current price positioning
      //
      IF close <= ExitPrice THEN
         EXITSHORT AT ExitPrice STOP
      ELSE
         EXITSHORT AT ExitPrice LIMIT
      ENDIF
   ELSE
      //
      //ExitShort AT MARKET when EXITPRICE does not meet the broker's minimun distance from current price
      //
      EXITSHORT AT Market
   ENDIF
ENDIF

It will add 10% to the current percentage every 50 minutes.

So if your base percentage was 10%, PerCentInc may have raised that to, say 11% or 12%, BarPerCent will add a further 10% for a total of 21% or 22%.

If you set up percentages like that:

• 10% BsaePerCent
• 10% PerCentInc
• 10% BarPerCent

when PerCentInc INCREASES  BasePerCent the first time, BasePerCent will become 11% (itself + 10% of itself), while BarPerCent will ADD 10% so that 11% becomes 21%.