Voici un exemple.
Veuillez donner à votre message un titre qui permette aux autres utilisateurs de comprendre de quoi il s’agit.
J’ai déplacé votre message sur le forum screener

p=1
//////////////////////////////Average candle size//////////////////////////////
x = 96

XGreen = 0
GreenSUM = 0
For i = 0 To x-1 Do
   GreenSUM = GreenSUM + Range[i]
   XGreen = XGreen + 1
   A = GreenSUM / XGreen
next

///////////////////////////////////////////////
length1=70
lenght2=50
/////////////////Resistance ///////////////////////////
if close>=highest[length1](close) then
   t1 = 0
   top1 = close
else
   top1 = top1
   t1 = t1+1
   if t1>lenght2 and t1<lenght2+2 then
      $TOPy[t+1] = top1
      $TOPx[t+1] = barindex
      $TopA[t+1]= A
      t=t+1
   endif
ENDIF

/////////////////Support ///////////////////////////
if close<=lowest[length1](close) then
   b1 = 0
   bot1 = close
else
   bot1 = bot1
   b1 = b1+1
   if b1>lenght2 and b1<lenght2+2 then
      $boty[r+1] = bot1
      $botx[r+1] = barindex
      $BotA[r+1]= A
      r=r+1
   endif
endif

signal1 = 0
for i=r downto max(0,r-30) do
   if  (low[p] < $BOTy[i] and high[p] > $BOTy[i]) or (low[p] < ($boty[i]+($BotA[i]*0.1)) and high[p] > ($BOTy[i]-($BotA[i]*0.2))) then
      Signal1 = 1
      break

   endif
next
signal2 = 0
for i=t downto max(0,t-30) do
   if (high[p] > $TOPy[i] and low[p] < $TOPy[i]) or (high[p] > ($TOPy[i]-($TopA[i]*0.05)) and low[p] < ($TOPy[i]+$TOPA[i]*0.2))then
      Signal2 = -1
      break

   endif
next

screener[signal1=1 or signal2=-1](signal1 as "S1", signal2 as "S2")