Bollinger %B su HA

Viewing 7 posts - 1 through 7 (of 7 total)

Author

Posts

05/21/2019 at 11:21 AM #98984 quote

Participant

Senior

Buongiorno,

è possibile avere un indicatore che disegni le candele HA in verde se il valore dell’indicatore Bollinger % B con valori valori 20.2 è maggiore di 50 e in rosso se il valore è minore di 50 e sempre in viola se l’indicatore è maggiore di 100 e -100.

Grazie

Saluti

05/21/2019 at 5:50 PM #99062 quote

robertogozzi

Moderator

Legend

Eccolo:

//DEFPARAM CalculateOnLastBars = 1000
// definizione delle candele HA
if barindex > 1 then
   xClose  = (open+close+low+high)/4    //TotalPrice
   xOpen   = (xOpen[1]+xClose[1])/2
   haHigh  = Max(xOpen, xClose)
   haLow   = Min(xOpen, xClose)
   xHigh   = Max(High,haHigh)
   xLow    = Min(Low,haLow)
   //xRange  = abs(xClose - xOpen)
else
   xClose  = (open+close+low+high)/4    //TotalPrice
   xOpen   = (Open[1]+Close[1])/2
   haHigh  = Max(xOpen, xClose)
   haLow   = Min(xOpen, xClose)
   xHigh   = Max(High,haHigh)
   xLow    = Min(Low,haLow)
   //xRange  = abs(xClose - xOpen)
endif
// Bollinger BB%
p       = 20
dev     = 2.0
BollInf = Average[p,0](xclose) - (dev * std[p](xclose))
BollSup = Average[p,0](xclose) + (dev * std[p](xclose))
pB      = ((xclose - BollInf) / (BollSup - BollInf)) * 100
//
// colore VIOLA per difetto
r = 186
g = 85
b = 211
// Visibilità massima
a = 255
//
IF pB <= 100 AND pB > 50 THEN
   r = 0
   g = 128                                //Verde
   b = 0
ELSIF pB >= -100 AND pB <= 50 THEN
   r = 255                                //Rosso
   g = 0
   b = 0
ENDIF
DRAWCANDLE(xOpen,xHigh,xLow,xClose) coloured(r,g,b,a)
return