Se puede hacer casi cualquier cosa.

Sólo que la Media Móvil Exponencial no se puede hacer con 300 períodos, sino sólo con alrededor de 60-70 debido al límite de 254 barras históricas.

Sin embargo, si tienes la versión Premium con un límite de 1024 barras, será posible utilizar 300 períodos.

Te lo haré lo antes posible, los códigos publicados en el foro no tienen ningún coste 🙂

Buenas!

A continuación, te proporciono el screener solicitado, que incluye las cuatro condiciones que mencionas:

1. Precio por encima de la media móvil exponencial de 300 periodos.
2. Variación del último trimestre mayor en un 5% respecto al trimestre anterior.
3. Potencial alcista de más del 10% respecto a los seis meses anteriores.
4. El porcentaje de veces que el MACD haya cruzado al alza su señal y el precio haya subido un 10%, con al menos un 50% de éxito (esto lo he puesto yo, además que he puesto que el 10% se haya obtenido antes de 20 velas).

// Condición A: Precio por encima de la media móvil exponencial de 300 periodos
CondicionA = Close > ExponentialAverage[300](Close)

// Condición B: Variación del último trimestre > 5% respecto al trimestre anterior
PrecioFinUltimoTrimestre = Close
PrecioInicioUltimoTrimestre = Close[64] // Aproximadamente 64 barras para un trimestre
PrecioFinTrimestreAnterior = Close[64] // El fin del trimestre anterior coincide con el inicio del último
PrecioInicioTrimestreAnterior = Close[128] // Precio de inicio del trimestre anterior

VariacionUltimoTrimestre = (PrecioFinUltimoTrimestre - PrecioInicioUltimoTrimestre) / PrecioInicioUltimoTrimestre * 100
VariacionTrimestreAnterior = (PrecioFinTrimestreAnterior - PrecioInicioTrimestreAnterior) / PrecioInicioTrimestreAnterior * 100
CondicionB = (VariacionUltimoTrimestre - VariacionTrimestreAnterior) > 5

// Condición C: Potencial alcista de más del 10% en los últimos seis meses
BarrasSeisMeses = 128 // Aproximadamente 128 barras para seis meses
PrecioHaceSeisMeses = Close[BarrasSeisMeses]
PrecioActual = Close
PotencialAlcista = ((PrecioActual - PrecioHaceSeisMeses) / PrecioHaceSeisMeses) * 100
CondicionC = PotencialAlcista > 10

// Condición D: % de veces que el MACD cruza al alza y el precio sube un 10%

// Definir variables para el conteo de cruces y éxitos
ContadorCruces = 0
ContadorExitos = 0

// Configuración del MACD
miMACDline = MACDLine[12, 26, 9](Close)
miMACDsignal = MACDSignal[12, 26, 9](Close)

// Bucle para revisar las últimas 100 barras
FOR i = 20 TO 100 DO
IF miMACDline[i] CROSSES OVER miMACDsignal[i] THEN
ContadorCruces = ContadorCruces + 1
PrecioCruce = Close[i]
        
// Verificar si después del cruce el precio sube un 10%
FOR j = i DOWNTO (i - 20) DO
IF Close[j] >= PrecioCruce * 1.10 THEN
ContadorExitos = ContadorExitos + 1
BREAK
ENDIF
NEXT
ENDIF
NEXT

// Cálculo del porcentaje de éxitos
IF ContadorCruces > 0 THEN
PorcentajeExitos = (ContadorExitos / ContadorCruces) * 100
ELSE
PorcentajeExitos = 0
ENDIF

// Condición: El porcentaje de éxitos debe ser mayor al 50%
CondicionD = PorcentajeExitos > 50

// Evaluar todas las condiciones
SCREENER[CondicionA AND CondicionB AND CondicionC AND CondicionD]

Aclaración condición D:

Contamos cuántas veces el MACD ha cruzado al alza su señal en las últimas 100 barras, y de esas veces, verificamos cuántas veces el precio ha subido un 10% en las siguientes 20 barras. Se cumple la condición si al menos el 50% de esos cruces resultaron en un aumento del 10%.

Buenas. Yo lo he pasado por la lista US Tech 150 y aparecen 3 valores.
De todas formas veo que no tienes la versión premium. Como te decía Roberto tendrás que ajustar los periodos porque sólo tienes 256 barras de datos. Con la premium tienes 1024.
Otra opción sería trabajar con velas semanales.