Hallo,
ich möchte gern das ein System am Dienstag (nur Dienstag) kauft, wenn der Kurs aus der Tagesrange vom Vortag (Montag) ausbricht. Ein Ausbruch am Mittwoch oder weitere Tage soll ignoriert werden!
Danke
Hier ist es (getestet am DAX, Daily):
Timeframe(Daily,UpdateOnClose)
IF DayOfWeek = 2 AND Not OnMarket THEN
BUY 1 CONTRACT AT high + 1+PipSize STOP
ENDIF
Timeframe(default)
SET STOP pLOSS 30
SET TARGET pPROFIT 60
Ich glaub es muss in einem kleineren Timeframe sein. 15 minunten
wenn der Kurs im mini Dax am Dienstag früh 1 punkt über das hoch von Montag geht, dann soll gekauft werden.
Ich möchte de Trade dann mit einem Timestop schließen zum Beispiel 17:45 Uhr
Schön wäre wenn ich einen Filter hätte zum Beispiel der Einstieg nur erfolgt, wenn das Volumen der Kerze 09 Uhr (Dienstag) 50 % höher ist als bei der 09 Uhr Kerze am Montag…
Danke noch mal…
Hier können Sie einen Intraday-Zeitrahmen Ihrer Wahl verwenden, 1 Stunde, 15 Minuten, 5 Minuten usw:
Timeframe(Daily,UpdateOnClose)
Entry = 9999999
IF DayOfWeek = 2 THEN
Entry = high + 1+PipSize
ENDIF
Timeframe(default)
IF OpenTime = 090000 THEN
PreviousVol = CurrentVol
CurrentVol = volume
ENDIF
IF Not OnMarket AND (CurrentVol > (PreviousVol * 1.5)) AND (close >= Entry) THEN
BUY 1 CONTRACT AT MARKET
ENDIF
IF Time = 174500 THEN
SELL AT MARKET
ENDIF
SET STOP pLOSS 200
SET TARGET pPROFIT 600
graphonprice Entry
Hallo,
ich möchte das der Code nur am 1. Dienstag im Monat einen Trade macht?
Ist das möglich?
Danke
Da ist er:
Timeframe(Daily,UpdateOnClose)
ONCE NewMonth = 0
IF Month <> Month[1] THEN
NewMonth = 1
ENDIF
Entry = 9999999
IF DayOfWeek = 2 AND NewMonth = 1 THEN
Entry = high + 1+PipSize
NewMonth = 0
ENDIF
Timeframe(default)
IF OpenTime = 090000 THEN
PreviousVol = CurrentVol
CurrentVol = volume
ENDIF
IF Not OnMarket AND (CurrentVol > (PreviousVol * 1.5)) AND (close >= Entry) THEN
BUY 1 CONTRACT AT MARKET
ENDIF
IF Time = 174500 THEN
SELL AT MARKET
ENDIF
SET STOP pLOSS 200
SET TARGET pPROFIT 600
graphonprice Entry
Hallo, danke das ist gut.
Leider eröffnet der Code nach jedem Exit noch einen neuen trade?
Können sie mir das mit dem Volumen rausmachen sodass der Trade einfach an jedem ersten dienstag eines Monats eröffnet wird wenn das vortageshoch von montag gebrochen wird. das am besten nach 153000 da ich es auf amerikanische aktien anwenden möchte
ich möchte aber gern das der trade nach x perioden geschlossen wird zum beispiel 5
Vielen Dank
Fertig:
Timeframe(Daily,UpdateOnClose)
ONCE NewMonth = 0
IF OpenMonth <> OpenMonth[1] THEN
NewMonth = 1
ENDIF
Entry = 9999999
IF DayOfWeek = 2 AND NewMonth = 1 THEN
Entry = high
NewMonth = 0
ENDIF
//
Timeframe(default)
IF ((NewMonth = 0) AND (NewMonth[1] = 1)) OR (Entry < Entry[1]) THEN
TradeOK = 1
ENDIF
IF Not OnMarket AND (close >= Entry) AND TradeOK AND (Time > 153000) AND (Time < 174500) THEN
BUY 1 CONTRACT AT MARKET
TradeOK = 0
ENDIF
IF OpenDayOfWeek > 2 THEN
TradeOK = 0
ENDIF
IF OnMarket AND ((Time >= 174500) OR ((BarIndex - TradeIndex) >= 5)) THEN //Beenden Sie nach 5 Kerzen
SELL AT MARKET
ENDIF
SET STOP pLOSS 20
SET TARGET pPROFIT 20
//graphonprice Entry coloured(0,0,255,255)
//graph NewMonth
//graph OpenMonth
//graph tradeOK
