E’ più comprensibile se indichi solo le condizioni, senza intervallarle dalle istruzioni.

Io ti avevo chiesto il riepilogo delle condizioni, non il codice.

Ok, ho capito.

Però devi adesso allegare il file ITF funzionante, altrimenti non posso provarlo perché in quello che hai postato mancano delle variabili (vedi foto).

x-5.jpg

Ho fatto queste modifiche:

• ho agginto la finestra temporale solo per la prima entrata
• ho aggiunto la variabile CONTO per sapere quale entrata è già stata fatta (questa variabile viene azzerata quando il TS non è a mercato, in modo da potere ricomniciare)
• ho modificato l’uscita parziale con ordini pendenti, in quanto non è consentita; le uscite parziali si possono fare solo con ordini a mercato; se usi ordini pendenti le uscite devono essere totali

DEFPARAM CumulateOrders = true // Posizioni cumulate disattivate

TIMEFRAME (4 hour, updateonclose)

MyLongEntry = low[0]
MyLongExit = high[1]
MyShortEntry = high[0]
MyShortExit = low[1]

TIMEFRAME (DEFAULT)

Finestra = time => 120000 and time <= 140000 and dayofweek <> 5

IF Not OnMarket THEN
conto = 0
ENDIF

stopluca = 60 // Stop Loss
TakeProfit = 60 // Take Profit (opzionale)
Mystop1 = 40 // Stop loss secondo ingresso
MyStop2 = 20 // Stop loss terzo ingresso
MyProfit1 = 20 // Take profit secondo ingresso
MyProfit2 = 40 // Take profit terzo ingresso
Position = 1
mymedia = ExponentialAverage[20](close)
CL1 = close > mymedia
CS1 = close < Mymedia
 
// condizioni per entrare long
 
IF CL1 AND Conto = 0 AND Finestra THEN
BUY Position CONTRACT AT Mylongentry limit
set stop ploss StopLuca
set target pprofit TakeProfit
Conto = 1
ENDIF
 
// condizione per uscire da posizioni long
 
if longonmarket then
//sell Position contract at mylongexit limit    //non si possono fare chiusure parziali con ordini pendenti
IF close >= mylongexit then
SELL Position contract at Market
endif
endif
 
// secondo ingresso long in caso il prezzo scenda di 20 pips dal mio prezzo di ingresso del primo ordine
 
if longonmarket and Conto = 1 then
buy 2 * Position contract at tradeprice - 20 * pipsize limit
set stop ploss MyStop1
set target pprofit MyProfit1
Conto = 2
endif
 
// terzo ingresso in caso il prezzo scenda di 40 pip dal prezzo di ingresso del primo ordine
 
if longonmarket and Conto = 2 then
buy 3 * Position contract at tradeprice - 40 * pipsize limit
set stop ploss MyStop2
set target pprofit MyProfit2
Conto = 3
endif
 
// Condizioni per entrare su posizioni short
 
IF CS1 and Conto = 0 AND Finestra THEN
SELLSHORT Position CONTRACT AT myshortentry limit
set stop ploss StopLuca
set target pprofit TakeProfit
Conto = 1
ENDIF
 
// condizione per uscire da posizioni short
 
if shortonmarket then
//exitshort Position contract at myshortexit limit //non si possono fare chiusure parziali con ordini pendenti
IF close <= myshortexit THEN
exitshort Position contract at Market
ENDIF
endif
 
// secondo ingresso short in caso il prezzo salga di 20 pips dal mio prezzo di ingresso del primo ordine
 
if shortonmarket and Conto = 1 then
sellshort 2 * Position contract at tradeprice + 20 * pipsize limit
set stop ploss MyStop1
set target pprofit MyProfit1
Conto = 2
endif
 
// terzo ingresso short in caso il prezzo salga di 40 pip dal prezzo di ingresso del primo ordine
 
if shortonmarket and Conto = 2 then
sellshort 3 * Position contract at tradeprice + 40 * pipsize limit
set stop ploss MyStop2
set target pprofit MyProfit2
Conto = 3
endif