This code snippet demonstrates how to calculate the Volume Weighted Average Price (VWAP) along with its standard deviation bands, similar to the internal VWAP indicator in ProRealTime’s trading platform. The code also includes color coding to indicate the direction of the VWAP and displays the previous day’s VWAP.

//PRC_VWAP Bands v11 intraday
//04/07/2022
//Nicolas @ www.prorealcode.com
//Sharing ProRealTime knowledge
d = max(1, intradaybarindex)
VWAP = SUMMATION[d](volume*typicalprice)/SUMMATION[d](volume)
if(intradaybarindex=0) then
  sd = 0
else
  p1 = SUMMATION[d](volume*typicalprice)
  p2 = SUMMATION[d](volume)
  p3 = SUMMATION[d](volume*typicalprice*typicalprice)
  ma = p1/p2
  ma2 = p3/p2
  sd = sqrt(abs(ma2 - ma * ma))
endif
SDup1 = vwap+sd
SDlw1 = vwap-sd
SDup2 = vwap+sd*2
SDlw2 = vwap-sd*2
SDup3 = vwap+sd*3
SDlw3 = vwap-sd*3
if vwap>vwap[1] then
  color = 1
else
  color = -1
endif
//yesterday vwap
if intradaybarindex=0 then
  yVWAP = VWAP[1]
endif
RETURN VWAP coloured by color as "VWAP", SDup1 coloured(102,102,102) as "upper 1 STD", SDlw1 coloured(102,102,102) as "lower 1 STD", SDup2 coloured(102,102,102) as "upper 2 STD", SDlw2 coloured(102,102,102) as "lower 2 STD", SDup3 coloured(102,102,102) as "upper 3 STD", SDlw3 coloured(102,102,102) as "lower 3 STD", yVWAP as "yesterday VWAP"

The code snippet above calculates the VWAP and its standard deviation bands for intraday trading analysis. Here’s a breakdown of the key components:

• d: This variable represents the number of bars since the start of the trading session. It is used as the period for the summation functions.
• VWAP Calculation: VWAP is calculated using the formula of the sum of (volume * typical price) divided by the sum of volume over ‘d’ bars.
• Standard Deviation Calculation: If it’s the first bar of the session (intradaybarindex=0), standard deviation (sd) is set to 0. Otherwise, it calculates the mean (ma) and the mean of the squares (ma2) to determine the variance, and the square root of the absolute variance gives the standard deviation.
• Standard Deviation Bands: These are calculated by adding or subtracting multiples of the standard deviation from the VWAP. This snippet calculates up to three standard deviations above and below the VWAP.
• Color Coding: The VWAP line is colored to indicate whether the current VWAP is higher or lower than the previous bar’s VWAP.
• Yesterday’s VWAP: At the start of each trading day, the VWAP from the previous day is stored and displayed.

This code is useful for traders who need to visualize price stability and volatility around the VWAP, which is often used as a benchmark for trading decisions.