Backtest of the ProRealTime software does not include overnight or overweek fees from your broker. You can either simulate it by adding fees into the backtest settings, thought that you knew that?

Hi Jebus,

I use limit orders with several of my systems. I have analyzed the differences between market and limit orders quite a lot, but not with backtesting as you can´t trust their results about that. For that I have run a  lot of systems in Demo with two versions market and limit orders being the only difference to compare results. My conclusions are that the limit orders tend to be better but not always. With limit orders in most of the trades you are going to get a little better result but you are going to miss several trades that tend to be good ones.

IMO the best type of order depends also of the system. The bigger the Timeframe the better for limit orders as there are more chances that the order is filled, And also the more trades the system makes the better for limit orders because if the system does very few trades you don´t want to miss any that can be the key for a good profit.

For reference if you are in a 1h Timeframe with a not big spread product (DAX, DOW, EURUSD…) using “AT CLOSE LIMIT” orders will make you miss about 5% of trades

I usually use in my systems this snippet than allow me to backtest/define more precisily my entry:

NENTRYLIMIT  = 5//Nº Velas máximo hasta que puede ejecutarse la orde al precio límite establecido en la señal de entrada. Si NENTRYLIMIT=0 se ejecutará directamente a mercado en la señal de entrada
MARKETENTRY   = 1//Si MARKETENTRY=1 se entrará a mercado después de los NENTRYLIMIT, en cambio si MARKETENTRY=0 no se entrará

LONGENTRY = LONGENTRY AND BARINDEX-LONGENTRYINDEX>=NENTRYLIMIT//Para que la entrada en "close limit" valga para ese nº de velas, sino se volvería a fijar el precio limit ante una nueva señal de entrada
SHORTENTRY = SHORTENTRY AND BARINDEX-SHORTENTRYINDEX>=NENTRYLIMIT//Para que la entrada en "close limit" valga para ese nº de velas, sino se volvería a fijar el precio limit ante una nueva señal de entrada

IF NENTRYLIMIT=0 THEN
IF LONGENTRY THEN
BUY LPOSITIONSIZE CONTRACTS AT MARKET
ELSIF SHORTENTRY THEN
SELLSHORT SPOSITIONSIZE CONTRACTS AT MARKET
ENDIF
ELSE
IF LONGENTRY THEN
BUY LPOSITIONSIZE CONTRACTS AT CLOSE LIMIT
LONGENTRYINDEX=BARINDEX
LONGENTRYPRICE=CLOSE
ELSIF SHORTENTRY THEN
SELLSHORT SPOSITIONSIZE CONTRACTS AT CLOSE LIMIT
SHORTENTRYINDEX=BARINDEX
SHORTENTRYPRICE=CLOSE
ENDIF
ENDIF

////PARA ENTRADA EN PRECIO LIMITE DURANTE N VELAS Y EN MARKET AL FINAL
IF NENTRYLIMIT>0 AND BARINDEX-TRADEINDEX>NENTRYLIMIT+1 AND BARINDEX-LONGENTRYINDEX<NENTRYLIMIT THEN
BUY LPOSITIONSIZE CONTRACTS AT LONGENTRYPRICE LIMIT
ELSIF NENTRYLIMIT>0 AND MARKETENTRY AND BARINDEX-TRADEINDEX>NENTRYLIMIT+1 AND BARINDEX-LONGENTRYINDEX=NENTRYLIMIT  THEN
BUY LPOSITIONSIZE CONTRACTS AT MARKET
ELSIF NENTRYLIMIT>0 AND NOT ONMARKET AND BARINDEX-TRADEINDEX>NENTRYLIMIT+1 AND BARINDEX-SHORTENTRYINDEX<NENTRYLIMIT THEN
SELLSHORT SPOSITIONSIZE CONTRACTS AT SHORTENTRYPRICE LIMIT
ELSIF NENTRYLIMIT>0 AND MARKETENTRY AND NOT ONMARKET AND BARINDEX-TRADEINDEX>NENTRYLIMIT+1 AND BARINDEX-SHORTENTRYINDEX=NENTRYLIMIT THEN
SELLSHORT SPOSITIONSIZE CONTRACTS AT MARKET
ENDIF
//*********************************************************************

With “NENTRYLIMIT ” I define how many bars after the entrysignal the trade can be made at the “close limit” of the entrybar, so with more bars to fullfill the order there are more chances to get it.

With “MARKETENTRY=1” if the order is not fullfiled after the bars defined in NENTRYLIMIT  then a market order is executed, with “MARKETENTRY=0” there is no market order