Lift up and down DAX 5M
Hi guys,
I want to share one of my DAX trading ideas based on cross over/under yesterdays high and low in combination with volatile intraday trading windows and certain week days. The approach is very simple works without indicators but seems to be very robust and reliable.
I have inserted Adolfo’s litle beauty concerning money management but fixed position size is possible as well (simply remove the comment).
Comments and improvements are welcome.
have fun
Reiner
// Lift up and down DAX 5M
// Code-Parameter
DEFPARAM FlatAfter = 113000
// trading window
ONCE BuyTime = 84500
ONCE SellTime = 113000
// money management
// variable position size - thanks Adolfo :-)
ONCE Capital = 10000
ONCE Risk = 0.01
ONCE StopLoss = 10
ONCE equity = Capital + StrategyProfit
ONCE maxrisk = round(equity*Risk)
ONCE PositionSize = abs(round((maxrisk/StopLoss)/PointValue)*pipsize)
// fixed position size
// ONCE PositionSize = 10
// manage number of trades
IF Time = BuyTime THEN
LongTradeCounter = 0
ShortTradeCounter = 0
ENDIF
// long on Monday until Thursday with filter close is above MA(14) and max 2 trades per day
IF Not LongOnMarket AND Time >= BuyTime AND close CROSSES OVER DHigh(1) AND close > Average[14](close) AND LongTradeCounter < 2 AND CurrentDayOfWeek <> 5 THEN
BUY PositionSize CONTRACT AT MARKET
LongTradeCounter = LongTradeCounter + 1
sl = 50
tp = 130
ENDIF
// short on Monday and Tuesday with filter close is under MA(9) and max 2 trades per day
IF Not ShortOnMarket AND Time >= BuyTime AND close CROSSES UNDER DLow(1) AND close < Average[9](close) AND ShortTradeCounter < 2 AND CurrentDayOfWeek < 3 THEN
SELLSHORT PositionSize CONTRACT AT MARKET
ShortTradeCounter = ShortTradeCounter + 1
sl = 90
tp = 30
ENDIF
// exit
IF LongOnMarket AND Time = SellTime THEN
SELL AT MARKET
ENDIF
IF ShortOnMarket AND Time = SellTime THEN
EXITSHORT AT MARKET
ENDIF
// stop and target
SET STOP pLOSS sl
SET TARGET pPROFIT tp
Comments
You must be logged in to post a comment.
Hi Reiner, can you build a system based on specification?
Hi Reiner,
I studied and tried this strategy on PRO demo account. I modified some parameter, Results seems reliable as backtest result. Trading performance seems not too bad except when some situations it caught by the New high / New low then U-Turn. This wil be painful. Is there any good indicator to prevent this ?
br,CKW
Hi Real Pro,
between 8:45 - 11:30 MEZ and every 5M candle check for a long trade if:
- system is not long
- close crosses over yesterdays high (please note this is the IG high and on Monday it's the high of Sunday)
- close ist greater then simple moving average[14]
- number of long trades is less 3 trades per day
- current day is not Friday
check for the short side
- System is not short
- close crosses under yesterdays low
- close ist less then simple moving average[9]
- number of short trades is less 3 (max 2 trades per day)
- current day is Monday or Tuesday
Trades will be closed:
- at 11:30
- system is long and the short conditions are true (close long and open short)
- system is short and the long conditions are true (close short and open long)
- stop or target levels will be achieved
That's it, very simple.
The general idea is to trade only on the first 2-3 trading hours, trade yesterdays high/low breakout with sl/tp and sort
out the week days where this system is not profitable. This idea works more or less in every index with enough volatile.
regards
Reiner
Reiner... please open a thread on this. I would like to share some information with you. I've studied it a lot... The optimization you have done on which index has been done? Only DAX? And on which period?
I've changed your parameter curve fitted with ATR and tested it on other indexes. there could be a possibility to put this live but I need your help to understand something.
Hey Reiner,
Thank you for all your work here!
If you register at IG, it is possible to do it with a link of prorealtime. That way prorealtime will give you the professional version of the software, which includes more histoical data.
Is it ok to post the link here? If not, please delete it.
https://trading.prorealtime.com/de/brokerage/cfd-forex-trading
But I am note sure if it can be done afterwards.
It also works in M15 timeframe. But with drawdown from May to October 2011.
The final performance with fixed position size on 8 years backtest is around the same as your test in M15.
Hello guys,
Thank you Reiner for your excellent work !
I put the code in real trades and until yesterday it took the trades. Did it happen to some of you ?
Best regards,
Roman