Hello,
I share my first strategy. Ichimoku is fashionable actually. So I tried to parameter a strategy on the Dax in m5 with a filter on UT, m15 and H1.
Taking losses and letting go of your winnings is the idea for TP and SL management.
The leverage is 5×1 € and a spread of 2. Test from January 2018 to now.
Good test and thank you for your feedback.

(google traduction, je suis français)

DEFPARAM CumulateOrders = false
DEFPARAM Preloadbars = 3000

// TAILLE DES POSITIONS

n = 5

// HORAIRES DE TRADING
TimeAchat = time >= 080500 and time < 152500
TimeVente = time >= 080500 and time < 152500


TIMEFRAME(60 minutes)

// INDICATEURS
Tenkansen1 = (highest[9](high)+lowest[9](low))/2
Kijunsen1 = (highest[26](high)+lowest[26](low))/2
SSpanA1 = (tenkansen1[26]+kijunsen1[26])/2
SSpanB1 = (highest[52](high[26])+lowest[52](low[26]))/2
Chikou1 = close

//////////////
// POSITION KUMO

// ACHAT
ca1m60 = (close > SSpanA1 and SSpanA1 > SSpanB1) or (close > SSpanB1 and SSpanB1 > SSpanA1)

// VENTE
cv1m60 = (close < SSpanA1 and SSpanA1 < SSpanB1) or (close < SSpanB1 and SSpanB1 < SSpanA1)

///////////////

// POSITION CHIKOU

// ACHAT
ca2m60 = Chikou1 > SSpanA1[26] and Chikou1 > SSpanB1[26]

// VENTE
cv2m60 = Chikou1 < SSpanA1[26] and Chikou1 < SSpanB1[26]

//////////////

TIMEFRAME(15 minutes)

// INDICATEURS
Tenkansen2 = (highest[9](high)+lowest[9](low))/2
Kijunsen2 = (highest[26](high)+lowest[26](low))/2
SSpanA2 = (tenkansen2[26]+kijunsen2[26])/2
SSpanB2 = (highest[52](high[26])+lowest[52](low[26]))/2
chikou2 = close

//////////////
// POSITION KUMO

// ACHAT
ca1m15 = (close > SSpanA2 and SSpanA2 > SSpanB2) or (close > SSpanB2 and SSpanB2 > SSpanA2)

// VENTE
cv1m15 = (close < SSpanA2 and SSpanA2 < SSpanB2) or (close < SSpanB2 and SSpanB2 < SSpanA2)

///////////////

// POSITION CHIKOU

// ACHAT
ca2m15 = Chikou2 > SSpanA2[26] and Chikou2 > SSpanB2[26]

// VENTE
cv2m15 = Chikou2 < SSpanA2[26] and Chikou2 < SSpanB2[26]

//////////////

TIMEFRAME(5 minutes)

IF intradaybarindex=0 then
 toto=0
ENDIF

// INDICATEURS
Tenkansen3 = (highest[9](high)+lowest[9](low))/2
Kijunsen3 = (highest[26](high)+lowest[26](low))/2
SSpanA3 = (tenkansen3[26]+kijunsen3[26])/2
SSpanB3 = (highest[52](high[26])+lowest[52](low[26]))/2


//////////////
// POSITION KUMO

// ACHAT
ca1m5 = (close > SSpanA3 and SSpanA3 > SSpanB3) or (close > SSpanB3 and SSpanB3 > SSpanA3)

// VENTE
cv1m5 = (close < SSpanA3 and SSpanA3 < SSpanB3) or (close < SSpanB3 and SSpanB3 < SSpanA3)

///////////////

// POSITION CHIKOU

// ACHAT
ca2m5 = close>SSpanA3 and close>SSpanB3 and close CROSSES OVER Kijunsen3 and close > Tenkansen3

// VENTE
cv2m5 = close<SSpanA3 and close<SSpanB3 and close CROSSES UNDER Kijunsen3 and close < Tenkansen3

//////////////

achat = (ca1m60 and ca2m60 and ca1m15 and ca2m15 and ca1m5 and ca2m5)
vente = (cv1m60 and cv2m60 and cv1m15 and cv2m15 and cv1m5 and cv2m5)

//////////////

IF achat and TimeAchat and not onmarket and toto=0 THEN
 toto=1
 Buy n shares at market
 SET STOP pLOSS 10
 SET TARGET pPROFIT 120
ENDIF

IF vente and TimeVente and not onmarket and toto=0 THEN
 toto=1
 Sellshort n shares at market
 SET STOP pLOSS 10
 SET TARGET pPROFIT 150
ENDIF