Here is the value chart indicator coded for the new ProRealTime v10.3 with custom candles made with DRAWCANDLE and alerts BUY/SELL arrows.

This indicator draw candlesticks over a normalized scale created dynamically from the last highest/lowest values over n period. It attempts to spot market oversold and overbought area on a short time scale, when price would revert to its mean value.

This kind of indicator is well used in binary options trading, in many different strategies.

When price make rebound over the oversold/overbought levels (candle spike rejection), arrows are drawn to specify trades entries.

//parameters :
//ExtDepth = 5
//Overbought = 8
//SlightlyOverbought = 6
//Oversold = -8
//SlightlyOversold = -6

if barindex>ExtDepth then
 sumHigh = summation[ExtDepth](high)
 sumLow = summation[ExtDepth](low)

 floatingaxis = 0.1 * (sumHigh+sumLow)
 volatilityunit = 0.04 * (sumHigh-sumLow)

 vcOpen = ((open-floatingaxis) / volatilityunit)
 vcClose =((close-floatingaxis) / volatilityunit)
 vcHigh = ((high-floatingaxis) / volatilityunit)
 vcLow = ((low-floatingaxis) / volatilityunit)

 if vcClose>vcOpen then
  DRAWCANDLE(vcOpen,vcHigh,vcLow,vcClose)coloured(10,240,10) bordercolor(0,200,0)
else
  DRAWCANDLE(vcOpen,vcHigh,vcLow,vcClose)coloured(240,10,10) bordercolor(200,0,0)
 endif

 if vcLow<Oversold and vcClose>SlightlyOversold then
  DRAWARROWUP(barindex,vcLow-0.5)coloured(10,255,10)
 endif

 if vcHigh>Overbought and vcClose<SlightlyOverbought then
  DRAWARROWDOWN(barindex,vcHigh+0.5)coloured(255,10,10)
 endif
endif

RETURN  Overbought COLOURED(250,250,250) STYLE(DOTTEDLINE,1)  as "overbought area", SlightlyOverbought COLOURED(250,250,250) STYLE(DOTTEDLINE,1) as "slightly overbought area", Oversold COLOURED(250,250,250) STYLE(DOTTEDLINE,1) as "oversold area", SlightlyOversold COLOURED(250,250,250) STYLE(DOTTEDLINE,1) as "slightly oversold area"