Discover the Super Trend Fisher Indicator: Analysis and Applications in ProRealTime

Introduction

The Super Trend Fisher indicator stands out as an advanced tool that combines several analytical methods to deliver clear and timely signals. This indicator is especially valued for its ability to adapt to different market conditions and its ease of integration into various trading strategies.

Description of the Super Trend Fisher Indicator

The Super Trend Fisher is a complex technical indicator that incorporates elements of the Detrended Price Oscillator, Fisher Transform, and the calculation of the Average True Range (ATR) to dynamically adjust trend levels. Its main goal is to identify the direction of the trend and signal possible reversals, using a methodology that adjusts its parameters in real-time to capture market volatility.

• Detrended Price Oscillator (DPO): Measures the deviation of the price from its moving average, helping to identify short-term price cycles stripped of long-term trends.
• Fisher Transform: Converts prices into a Gaussian distribution to produce clearer and timelier signals.
• Average True Range (ATR): Used to calculate market volatility, the ATR helps adjust the SuperTrend thresholds to be more responsive during volatile market conditions.
• SuperTrend: Combines direction of the trend and volatility, offering a clear visual summary of the current market situation.

Functioning of the Indicator

The Super Trend Fisher uses a combination of analytical techniques to provide an integrated and deeply contextual view of market behavior. Below is an explanation of how each component of the indicator is calculated:

• Calculation of the Detrended Price Oscillator: The moving average is subtracted from the closing price, which helps eliminate long-term price variations and focus on short-term fluctuations.
• Application of the Fisher Transform: This transform alters the distribution of price data to make overbought and oversold areas more identifiable and accessible for technical analysis.
• Integration of the ATR: The ATR adjusts the limits of the SuperTrend according to market volatility, allowing the indicator to be effective under different market conditions.

Practical Applications

The Super Trend Fisher indicator is exceptionally useful for traders looking to quickly identify market trends and reversal points. Here are some ways to interpret the signals provided by this indicator:

• Trend Identification: When the indicator moves above the zero level and changes color, it indicates a possible entry into an uptrend. Conversely, a movement below the zero level with a color change suggests a downtrend.
• Buy and Sell Signals: A buy signal may be considered when the Super Trend Fisher changes from red to green and is above the zero line. Conversely, a sell signal is suggested when it changes from green to red and is located below the zero line.
• Optimization of Entries and Exits: Combining the Super Trend Fisher with other momentum or volume indicators can help refine entries and exits, thereby improving risk management and the effectiveness of trading strategies.

Setup and Customization

Copy and paste the code provided in the programming section of the editor. Adjust the parameters period, length, len, stFactor, and stPeriod according to your specific needs to tailor the sensitivity and reactivity of the indicator.

//-------------------------------------------------------------------------//
//PRC_SuperTrend Fisher
//version = 0
//16.04.24
//Iván González @ www.prorealcode.com
//Sharing ProRealTime knowledge
//-------------------------------------------------------------------------//
//-----Inputs--------------------------------------------------------------//
period=14//Fair-value Period
length=14//EMA length
len=9//Fisher Period
stFactor=0.3//SuperTrend Factor
stPeriod=10//SuperTrend Period
l=20//Hma period
//-------------------------------------------------------------------------//
n=max(period,max(l,length))*3
//-----Detrended Price Oscillator + Standard deviation---------------------//
barsback=round(period/2)+1
ma=average[period](close)
dpo1=close-ma[barsback]
sd = dpo1/(average[period,1](high-low))*100
//-------------------------------------------------------------------------//
//-----Fisher Transform Formula + Smoothing--------------------------------//
src=sd
high1=highest[len](src)
low1=lowest[len](src)
if barindex <= n then
myvalue=src
fish1=src
MAfish=src
else
val=0.66*((src-low1)/(high1-low1)-0.5)+0.67*myvalue[1]

if val > 0.99 then
myvalue=0.999
elsif val < -0.99 then
myvalue=-0.999
else
myvalue=val
endif
fish1= 0.5*log((1+myvalue)/(1-myvalue))+0.5*mafish1[1]
mafish1=hullaverage[l](fish1)
endif
//-------------------------------------------------------------------------//
source=mafish1
//-------------------------------------------------------------------------//
//-----ATR from Fisher transformation--------------------------------------//
hh=highest[stPeriod](source)
ll=lowest[stPeriod](source)
if barindex<=stPeriod then
trueRange=hh-ll
else
trueRange=max(max(hh-ll,abs(hh-source[1])),abs(ll-source[1]))
endif
alpha = 1/stPeriod
if barindex <= n then
atr = average[stPeriod](trueRange)
else
atr = alpha*trueRange + (1-alpha)*atr[1]
endif
//-------------------------------------------------------------------------//
//-----Supertrend Integration----------------------------------------------//
upperband=source+stFactor*atr
lowerband=source-stFactor*atr

if barindex <= n then
prevLowerband=source
prevUpperband=source
else
prevLowerband=lowerband[1]
prevUpperband=upperband[1]

if lowerband>prevlowerband or source[1]<prevlowerband then
lowerband=lowerband
else
lowerband=prevlowerband
endif

if upperband < prevupperband or source[1]>prevupperband then
upperband=upperband
else
upperband=prevupperband
endif
endif

prevStvalue=stvalue[1]
if prevStValue = prevupperband then
if source > upperband then
stdirection = -1
else
stdirection = 1
endif
else
if source < lowerband then
stdirection = 1
else
stdirection = -1
endif

endif
if stdirection = -1 then
stvalue=lowerband
else
stvalue=upperband
endif

q2= average[length,1](source)
//-------------------------------------------------------------------------//
//-----Overbought and Oversold Bands---------------------------------------//
obLevel = 4.0
osLevel = -4.0
obupper = obLevel
obmid = obLevel+0.9
oblower = obLevel + 2
osupper = osLevel
osmid = osLevel - 0.9
oslower = osLevel - 2
//-------------------------------------------------------------------------//
//-----Color definition----------------------------------------------------//
if source > stValue then
r =0
g=255
else
r=255
g=0
endif
if barindex > n then
colorbetween(source,stvalue,r,g,0,90)

colorbetween(obupper, oblower,"red",50)
colorbetween(osupper, oslower,"green",50)
colorbetween(obmid, oblower,"red",50)
colorbetween(osmid, oslower,"green",50)
endif
//-------------------------------------------------------------------------//
return q2 as "ema fish"coloured(120,123,134)style(line,2),source as "Fish"coloured(r,g,0),stValue as "StValue"coloured(r,g,0),0 as "0" coloured(121,121,121)

• Application and Analysis: Once the code is adjusted, apply the indicator to the chart. Observe how the indicator interacts with price movements and adjust settings if necessary to optimize signals.

Conclusions

The Super Trend Fisher indicator offers a robust combination of technical analysis and adaptability, making it a valuable tool for any trader. Its ability to integrate multiple analytical techniques into a single indicator allows for a richer and more nuanced interpretation of the markets. As with any trading tool, it is recommended to combine the Super Trend Fisher with proper risk management and a coherent trading strategy.