“Market Sentiment Dashboard for Ichimoku”

This program visualizes in 7 columns all the inter-actions that can occur between the five elements component system “Ichimoku Kinko Hyo”.
Usable on any unit of time, it can serve as a basis for designing long automated strategies or medium term using internal routines (custom developments) or assisting in decision-making before initiating a stock market transaction. In short, this leaves the door open to new ideas …

Characteristics of columns from right to left
– SMA: Price evolution based on simple average at 200 periods (bias for preferential intervention zone) Bullish orientation “green triangle”, bearish “red triangle” or neutral “smiley” (with subliminal message)
– Market Feeling: Progression of the signal according to the arrangement of the elements between them (low, medium, strong, extreme)
– Price: Price environment with Tenkan-sen, Kijun-sen, Senkou-span approach, inside the cloud “Kumo”
– Kijun: Tenkan and Kijun junction (entrance, exit Kumo) Katana detection (Tenkan and Kijun overlay)
– Cloud: “Kumo or cloud” price behavior in contact with the Senkou-span, inside the cloud or at the exit
– Tenkan: Behavior of the Tenkan-sen at the entrance, exit or in the cloud and crossing of the Senkou-span
– Lagging: “Chikou span” Observation of the memory of the market (26 periods back) and obstacle to cross

Four columns (external variables) can be hidden as well as the “Label” line at the bottom of the indicator

Main events:
– Detection of a Katana (juxtaposition of the Tenkan on the Kijun) summation for validation of the pattern
– Crossing the Tenkan-sen and Kijun-sen lines offering a favorable entry area for initiating a position
– Detection of a “Twist Cross“, crossing Senkou-span SA by Senkou-span SB or inverse (orientation of the cloud)
– Detection of a “Twist Flat“, superposition of 2 Senkou-span on some candles (lateralization, range)

Other indicators related to the system “Ichimoku Kinko Hyo” are under study and will be distributed after their validation phases completed.
For any questions about the program “Ichiba Kimochi” please make your request here ► …https://www.prorealcode.com/topic/ichiba-kimochi-dashboard/

// Ichiba Kimochi DashBoard Signal | Indicator
// 14/04/2019 (Release 1.0)
// Swapping @ www.forexswap.fr
// Sharing ProRealTime knowledge (alt+16)
// Ichiba = marché (marketplace), Kimochi = humeur (sentiment) "Tableau du sentiment de marché"

// --- Property settings
DefParam DrawOnLastBarOnly = true
// Price   = 1 // (1=true/0=false)
// Kijun   = 1 //      ------
// Cloud   = 1 //      ------
// Lagging = 1 //      ------
// Label   = 1 //      ------
// --- end

Tenkansen = (highest[9](High)+lowest[9](Low))/2
Kijunsen  = (highest[26](High)+lowest[26](Low))/2
//Chikou    = Close[26]
SenkouSA  = (Tenkansen[26]+Kijunsen[26])/2
SenkouSB  = (highest[52](High[26])+lowest[52](Low[26]))/2

// Check Box "Price"
if price = 1 then
if close > Tenkansen then
DrawText("Price » Tenkan",barindex-65,0.75,SansSerif,Standard,17) coloured(0,160,250)
DrawRectangle(barindex-52,0.95,barindex-78,-0.95) coloured(0,0,0,33)
elsif close < Tenkansen then
DrawText("Price « Tenkan",barindex-65,0.5,SansSerif,Standard,17) coloured(0,160,250)
DrawRectangle(barindex-52,0.95,barindex-78,-0.95) coloured(0,0,0,33)
elsif close > Kijunsen then
DrawText("Price » Kijun",barindex-65,0.25,SansSerif,Standard,17) coloured(0,160,250)
DrawRectangle(barindex-52,0.95,barindex-78,-0.95) coloured(0,0,0,33)
elsif close < Kijunsen then
DrawText("Price « Kijun",barindex-65,0.0,SansSerif,Standard,17) coloured(0,160,250)
DrawRectangle(barindex-52,0.95,barindex-78,-0.95) coloured(0,0,0,33)
endif

if close crosses over SenkouSA and SenkouSA < SenkouSB then
DrawText("Price ╦ Kumo",barindex-65,0.25,SansSerif,Standard,17) coloured(10,190,0)  // alt+203 ╦
DrawRectangle(barindex-52,0.95,barindex-78,-0.95) coloured(0,0,0,33)
elsif close crosses over SenkouSA then
DrawText("Price ↑ SSA",barindex-65,0.25,SansSerif,Standard,17) coloured(10,190,0)    // alt+24 ↑
DrawRectangle(barindex-52,0.95,barindex-78,-0.95) coloured(0,0,0,33)
elsif close crosses under SenkouSA and SenkouSA < SenkouSB then
DrawText("Price ↓ SSA",barindex-65,-0.25,SansSerif,Standard,17) coloured(190,10,0)   // alt+25 ↓
DrawRectangle(barindex-52,0.95,barindex-78,-0.95) coloured(0,0,0,33)
elsif close crosses under SenkouSA then
DrawText("Price ╩ Kumo",barindex-65,-0.25,SansSerif,Standard,17) coloured(190,10,0) // alt+202 ╩
DrawRectangle(barindex-52,0.95,barindex-78,-0.95) coloured(0,0,0,33)
endif

if close crosses over SenkouSB then
DrawText("Price ╦ Kumo",barindex-65,-0.75,SansSerif,Standard,17) coloured(10,190,0) // alt+203 ╦
DrawRectangle(barindex-52,0.95,barindex-78,-0.95) coloured(0,0,0,33)
elsif close crosses over SenkouSB and SenkouSB > SenkouSA then
DrawText("Price ↑ SSB",barindex-65,-0.75,SansSerif,Standard,17) coloured(10,190,0)   // alt+24 ↑
DrawRectangle(barindex-52,0.95,barindex-78,-0.95) coloured(0,0,0,33)
elsif close crosses under SenkouSB and SenkouSB < SenkouSA then
DrawText("Price ↓ SSB",barindex-65,-0.5,SansSerif,Standard,17) coloured(190,10,0)    // alt+25 ↓
DrawRectangle(barindex-52,0.95,barindex-78,-0.95) coloured(0,0,0,33)
elsif close crosses under SenkouSB then
DrawText("Price ╩ Kumo",barindex-65,-0.5,SansSerif,Standard,17) coloured(190,10,0)  // alt+202 ╩
DrawRectangle(barindex-52,0.95,barindex-78,-0.95) coloured(0,0,0,33)
endif
endif

// Check Box "Kijun"
if Kijun = 1 then
if Tenkansen crosses over Kijunsen then
DrawText("Tenkan ↑ Kijun",barindex-95,0.0,MonoSpaced,Bold,17) coloured(250,160,0)     // alt+24 ↑
DrawRectangle(barindex-82,0.95,barindex-108,-0.95) coloured(0,0,0,33)
elsif Tenkansen crosses under Kijunsen then
DrawText("Tenkan ↓ Kijun",barindex-95,-0.0,MonoSpaced,Bold,17) coloured(250,160,0)    // alt+25 ↓
DrawRectangle(barindex-82,0.95,barindex-108,-0.95) coloured(0,0,0,33)
elsif Tenkansen > Kijunsen then
DrawText("Tenkan » Kijun",barindex-95,0.5,SansSerif,Standard,17) coloured(0,160,250)  //alt+175 »
DrawRectangle(barindex-82,0.95,barindex-108,-0.95) coloured(0,0,0,33)
elsif Tenkansen < Kijunsen then
DrawText("Tenkan « Kijun",barindex-95,-0.5,SansSerif,Standard,17) coloured(0,160,250) //alt+174 «
DrawRectangle(barindex-82,0.95,barindex-108,-0.95) coloured(0,0,0,33)
elsif Tenkansen = Kijunsen and Tenkansen[1] = Kijunsen[1] then                           // Spécial event
DrawText("• Katana",barindex-95,-0.0,MonoSpaced,Bold,17) coloured(250,160,0)          // alt+7 •
DrawRectangle(barindex-82,0.95,barindex-108,-0.95) coloured(0,0,0,33)
endif
endif

if Tenkansen crosses over SenkouSA and SenkouSA < SenkouSB then
DrawText("Tenkan ╦ Kumo Lo",barindex-155,-0.5,SansSerif,Standard,17) coloured(10,190,0) // alt+203 ╦
DrawRectangle(barindex-142,0.95,barindex-168,-0.95) coloured(0,0,0,33)
elsif Tenkansen crosses over SenkouSB and SenkouSB > SenkouSA then
DrawText("Tenkan ↑ Kumo Lo",barindex-155,-0.25,SansSerif,Standard,17) coloured(10,190,0) // alt+24 ↑
DrawRectangle(barindex-142,0.95,barindex-168,-0.95) coloured(0,0,0,33)
elsif Tenkansen crosses over SenkouSB and SenkouSA > SenkouSB then
DrawText("Tenkan ╦ Kumo Hi",barindex-155,0.75,SansSerif,Standard,17) coloured(10,190,0) // alt+203 ╦
DrawRectangle(barindex-142,0.95,barindex-168,-0.95) coloured(0,0,0,33)
elsif Tenkansen crosses under SenkouSA and SenkouSA < SenkouSB then
DrawText("Tenkan ╩ Kumo Lo",barindex-155,0.5,SansSerif,Standard,17) coloured(190,10,0)  // alt+202 ╩
DrawRectangle(barindex-142,0.95,barindex-168,-0.95) coloured(0,0,0,33)
elsif Tenkansen crosses under SenkouSA and SenkouSA > SenkouSB then
DrawText("Tenkan ╩ Kumo Hi",barindex-155,0.5,SansSerif,Standard,17) coloured(190,10,0)  // alt+202 ╩
DrawRectangle(barindex-142,0.95,barindex-168,-0.95) coloured(0,0,0,33)
elsif Tenkansen crosses over SenkouSA then
DrawText("Tenkan ╦ SSA",barindex-155,0.25,SansSerif,Standard,17) coloured(0,180,250)    // alt+203 ╦
DrawRectangle(barindex-142,0.95,barindex-168,-0.95) coloured(0,0,0,33)
elsif Tenkansen crosses under SenkouSA then
DrawText("Tenkan ╩ SSA",barindex-155,0.25,SansSerif,Standard,17) coloured(190,10,0)     // alt+202 ╩
DrawRectangle(barindex-142,0.95,barindex-168,-0.95) coloured(0,0,0,33)
elsif Tenkansen crosses over SenkouSB then
DrawText("Tenkan ╦ SSB",barindex-155,-0.0,SansSerif,Standard,17) coloured(0,180,250)    // alt+203 ╦
DrawRectangle(barindex-142,0.95,barindex-168,-0.95) coloured(0,0,0,33)
elsif Tenkansen crosses under SenkouSB then
DrawText("Tenkan ↓ SSB",barindex-155,-0.0,SansSerif,Standard,17) coloured(190,10,0)      // alt+25 ↓
DrawRectangle(barindex-142,0.95,barindex-168,-0.95) coloured(0,0,0,33)
endif

// Check Box "Cloud"
if Cloud = 1 then
if close > SenkouSB and SenkouSB > SenkouSA then
DrawText("Price » Kumo Lo",barindex-125,-0.5,SansSerif,Standard,17) coloured(0,160,250)
DrawRectangle(barindex-112,0.95,barindex-138,-0.95) coloured(0,0,0,33)
elsif close < SenkouSB and close > SenkouSA then
DrawText("Price ↔ Kumo Lo",barindex-125,-0.25,SansSerif,Standard,17) coloured(0,160,250)
DrawRectangle(barindex-112,0.95,barindex-138,-0.95) coloured(0,0,0,33)
elsif close < SenkouSA and SenkouSA < SenkouSB then
DrawText("Price « Kumo Lo",barindex-125,-0.75,SansSerif,Standard,17) coloured(0,160,250)
DrawRectangle(barindex-112,0.95,barindex-138,-0.95) coloured(0,0,0,33)
elsif close > SenkouSA and SenkouSA > SenkouSB then
DrawText("Price » Kumo Hi",barindex-125,0.75,SansSerif,Standard,17) coloured(0,160,250)
DrawRectangle(barindex-112,0.95,barindex-138,-0.95) coloured(0,0,0,33)
elsif close < SenkouSB and SenkouSB < SenkouSA then
DrawText("Price « Kumo Hi",barindex-125,0.5,SansSerif,Standard,17) coloured(0,160,250)
DrawRectangle(barindex-112,0.95,barindex-138,-0.95) coloured(0,0,0,33)
elsif close < SenkouSA and close > SenkouSB then
DrawText("Price ↔ Kumo Hi",barindex-125,0.25,SansSerif,Standard,17) coloured(0,160,250)
DrawRectangle(barindex-112,0.95,barindex-138,-0.95) coloured(0,0,0,33)
elsif close crosses over SenkouSA then
DrawText("Price ╩ SSA",barindex-65,0.5,SansSerif,Standard,17) coloured(10,190,0)   // alt+202 ╩
DrawRectangle(barindex-22,0.95,barindex-48,-0.95) coloured(0,0,0,33)
elsif close crosses over SenkouSB then
DrawText("Price ╩ SSB",barindex-65,0.25,SansSerif,Standard,17) coloured(10,190,0)  // alt+202 ╩
DrawRectangle(barindex-22,0.95,barindex-48,-0.95) coloured(0,0,0,33)
elsif close crosses under SenkouSA then
DrawText("Price ╦ SSA",barindex-65,-0.25,SansSerif,Standard,17) coloured(190,10,0) // alt+203 ╦
DrawRectangle(barindex-22,0.95,barindex-48,-0.95) coloured(0,0,0,33)
elsif close crosses under SenkouSB then
DrawText("Price ╦ SSB",barindex-65,-0.5,SansSerif,Standard,17) coloured(190,10,0)  // alt+203 ╦
DrawRectangle(barindex-22,0.95,barindex-48,-0.95) coloured(0,0,0,33)
endif
if SenkouSA crosses over SenkouSB or SenkouSA crosses under SenkouSB then              // Spécial event
DrawText("• Twist cross",barindex-125,0.0,MonoSpaced,Bold,17) coloured(250,160,0)   // alt+7 •
DrawRectangle(barindex-112,0.95,barindex-138,-0.95) coloured(0,0,0,33)
endif
if SenkouSA = SenkouSB then                                                            // Spécial event
DrawText("• Twist Flat",barindex-125,-0.75,MonoSpaced,Bold,17) coloured(250,160,0)  // alt+7 •
DrawRectangle(barindex-112,0.95,barindex-138,-0.95) coloured(0,0,0,33)
endif
endif

// Check Box "Lagging Span"
if Lagging = 1 then
if close > tenkansen[26] and close > kijunsen[26] and close > senkousa[26] and close > senkousb[26]and close > high[26] then
DrawText("Free High Area",barindex-185,0.75,SansSerif,Standard,17) coloured(0,160,250) // alt+175 »
DrawRectangle(barindex-172,0.95,barindex-198,-0.95) coloured(0,0,0,33)                 // Chikou » High
endif
if close crosses over tenkansen[26] or close crosses under tenkansen[26] then
DrawText("Chikou cross Tenkan",barindex-185,0.50,SansSerif,Standard,17) coloured(0,160,250)
DrawRectangle(barindex-172,0.95,barindex-198,-0.95) coloured(0,0,0,33)
endif
if close crosses over kijunsen[26] or close crosses under kijunsen[26] then
DrawText("Chikou cross Kijun",barindex-185,0.25,SansSerif,Standard,17) coloured(0,160,250)
DrawRectangle(barindex-172,0.95,barindex-198,-0.95) coloured(0,0,0,33)
endif
if close crosses over senkousa[26] or close crosses under senkousa[26] or close crosses over senkousb[26] or close crosses under senkousb[26] then
DrawText("Chikou ↕ Senkou",barindex-185,-0.25,SansSerif,Standard,17) coloured(0,160,250) // alt+18 ↕
DrawRectangle(barindex-172,0.95,barindex-198,-0.95) coloured(0,0,0,33)
endif
if close < senkousa[26] and close > senkousb[26] or close > senkousb[26] and close < senkousa[26] then
DrawText("Chikou ↔ Kumo",barindex-185,-0.5,SansSerif,Standard,17) coloured(0,160,250)   // alt+18 ↕
DrawRectangle(barindex-172,0.95,barindex-198,-0.95) coloured(0,0,0,33)
endif
if close < tenkansen[26] and close < kijunsen[26] and close < senkousa[26] and close < senkousb[26]and close < high[26] then
DrawText("Free Low Area",barindex-185,-0.75,SansSerif,Standard,17) coloured(0,160,250)   // alt174 «
DrawRectangle(barindex-172,0.95,barindex-198,-0.95) coloured(0,0,0,33)                   // Chikou « Low
endif
// Do Not Use "Wait solution"
//LagCross = (SenkouSA crosses over SenkouSB or SenkouSA crosses under SenkouSB)              // Spécial event Twist Chikou
//if close[26] crosses over LagCross[26] or close[26] crosses under LagCross[26] then
//DrawText("• Twist Chikou",barindex-185,0.0,MonoSpaced,Bold,17) coloured(250,160,0)       // alt+7 •
//endif
endif

// Box "Trend Strength Market Long"
if close > senkousa and senkousa > senkousb and close > tenkansen and tenkansen > kijunsen and close > high[26] then
DrawText("Fujisan market",barindex-34,0.70,Dialog,Bold,16) coloured(10,190,0)
DrawText("■",barindex-22,0.68,Dialog,Bold,16) coloured(10,250,0,240)         // alt+254 ■
DrawRectangle(barindex-23,0.95,barindex-48,-0.95) coloured(0,0,0,33)
endif
if close > senkousa and senkousa > senkousb and close > tenkansen and tenkansen > kijunsen then
DrawText("Strong",barindex-34,0.46,Dialog,Bold,14) coloured(10,190,0)
DrawText("■",barindex-22,0.46,Dialog,Bold,16) coloured(10,190,0,220)
endif
if close > senkousa and senkousa > senkousb and close > kijunsen then
DrawText("Medium",barindex-34,0.22,Dialog,Bold,13) coloured(10,190,0)
DrawText("■",barindex-22,0.23,Dialog,Bold,16) coloured(10,190,0,150)
endif
if close > senkousa and senkousa > senkousb then
DrawText("Poor",barindex-34,0.0,Dialog,Bold,12) coloured(250,160,0)
DrawText("■",barindex-22,-0.0,Dialog,Bold,16) coloured(250,160,0,120)
endif
// Box "Trend Strength Market Short"
if close < senkousa and senkousa < senkousb and tenkansen < kijunsen and close < tenkansen and close < low[26] then
DrawText("Abysse market",barindex-34,-0.70,Dialog,Bold,16) coloured(190,10,0)
DrawText("■",barindex-22,-0.68,Dialog,Bold,16) coloured(255,10,0,255)         // alt+254 ■
DrawRectangle(barindex-23,0.95,barindex-48,-0.95) coloured(0,0,0,33)
endif
if close < senkousa and senkousa < senkousb and tenkansen < kijunsen and close < tenkansen then
DrawText("Strong",barindex-34,-0.46,Dialog,Bold,14) coloured(190,10,0,255)
DrawText("■",barindex-22,-0.46,Dialog,Bold,16) coloured(220,10,0,200)
endif
if close < senkousa and senkousa < senkousb and close < kijunsen then
DrawText("Medium",barindex-34,-0.22,Dialog,Bold,13) coloured(190,10,0)
DrawText("■",barindex-22,-0.23,Dialog,Bold,16) coloured(190,10,0,150)
endif
if close < senkousa and senkousa < senkousb then
DrawText("Poor",barindex-34,-0.0,Dialog,Bold,12) coloured(250,160,0)
DrawText("■",barindex-22,-0.0,Dialog,Bold,16) coloured(250,160,0,120)
endif

// Box "Simple Moving Average 200" (add indicator "Crossing SMA200.itf" to graph price)
SMA200 = average[200]
if close > SMA200 and close[1] > SMA200 then
DrawText(" ▲ ",barindex[9],0.19,MonoSpaced,Standard,23) coloured(10,240,0)
DrawText("▬ ▬ ▬ ▬",barindex[9],0.0,Serif,Standard,10) coloured(10,190,0)     // alt+7 •
DrawEllipse(barindex[13],0.43,barindex-5,-0.43) coloured(10,190,0)             // Optional
elsif close < SMA200 and close[1] < SMA200 then
DrawText(" ▼ ",barindex[9],-0.22,MonoSpaced,Standard,23) coloured(240,10,0)
DrawText("▬ ▬ ▬ ▬",barindex[9],0.0,Serif,Standard,10) coloured(190,10,0)     // alt+7 •
DrawEllipse(barindex[13],0.43,barindex-5,-0.43) coloured(190,10,0)             // Optional
elsif close crosses over SMA200 or close crosses under SMA200 then                // Neutral Area
DrawText(" ☻ ",barindex[9],0.0,MonoSpaced,Standard,21) coloured(250,160,0)    // alt+2 ☻
DrawText(" ☼ ",barindex[9],0.0,MonoSpaced,Standard,30) coloured(250,160,0)    // alt+15 ☼
DrawEllipse(barindex[13],0.43,barindex-5,-0.43) coloured(250,160,0)
DrawText("Trend is your friend",barindex[9],0.8,Dialog,Bold,11) coloured(250,160,0)
DrawText("Wait for Trade",barindex[9],0.6,Dialog,Bold,10) coloured(250,160,0)  // advertise
DrawText("Forexswap.fr",barindex[9],-0.65,Dialog,Standard,11) coloured(0,0,0)  //   ----
endif

// Check Box "Label String"
if label = 1 then
DrawText("SMA",barindex-9,-0.91,MonoSpaced,Italic,12)
//DrawRectangle(barindex-5,0.95,barindex-13,-0.95) coloured(0,0,0,33)
DrawText("Market Feeling",barindex-34,-0.91,MonoSpaced,Italic,12)
//DrawRectangle(barindex-23,0.95,barindex-48,-0.95) coloured(0,0,0,33)
DrawText("Price",barindex-65,-0.91,MonoSpaced,Italic,12)
//DrawRectangle(barindex-52,0.95,barindex-78,-0.95) coloured(0,0,0,33)
DrawText("Kijun",barindex-95,-0.91,MonoSpaced,Italic,12)
//DrawRectangle(barindex-82,0.95,barindex-108,-0.95) coloured(0,0,0,33)
DrawText("Cloud",barindex-125,-0.91,MonoSpaced,Italic,12)
//DrawRectangle(barindex-112,0.95,barindex-138,-0.95) coloured(0,0,0,33)
DrawText("Tenkan",barindex-155,-0.91,MonoSpaced,Italic,12)
//DrawRectangle(barindex-142,0.95,barindex-168,-0.95) coloured(0,0,0,33)
DrawText("Lagging Span",barindex-185,-0.91,MonoSpaced,Italic,12)
//DrawRectangle(barindex-172,0.95,barindex-198,-0.95) coloured(0,0,0,33)
//DrawText("Spare 215",barindex-215,-0.91,MonoSpaced,Italic,12)                       // for further developments
//DrawRectangle(barindex-202,0.95,barindex-228,-0.95) coloured(0,0,0,33)                // for further developments
//DrawText("Red 190,10,0    ",barindex-245,0.6,MonoSpaced,bold,17) coloured(190,10,0)   // color code
//DrawText("Blue 0,160,250  ",barindex-245,0.3,MonoSpaced,bold,17) coloured(0,160,250)  // color code
//DrawText("Green 10,190,0  ",barindex-245,0.0,MonoSpaced,bold,17) coloured(10,190,0)   // color code
//DrawText("Yellow 250,160,0",barindex-245,-0.3,MonoSpaced,bold,17) coloured(250,160,0) // color code

// --- Gadget "current date" European format (clear 4 "REM" following to use gadget)
cday   = day
cmonth = month
cyear  = year
DrawText("#cDay#/ #cMonth#/ #cYear#",barindex,-0.90,SansSerif,BoldItalic,11)
// --- end Gadget
endif

return