The indicator DayImpuls T3 v3 is basically based on the combination of a DayImpuls with a T3 moving average.

This oscillator will inform you on both the trend and the strength of the market by measuring the slope of the moving average T3.
A rather bullish market is characterized by a position of the oscillator above level 0 and a rather bearish market by a position lower than this one.

The indicator also has 2 upper and lower bands, representing the last highest and last lowest of the oscillator according to periods that adapt automatically according to the timeframe on which the oscillator is active.

Indicator converted from MT4 version by a request in the English indicator’s forum.

//PRC_DayImpuls T3 v3 | indicator
//02.11.2017
//Nicolas @ www.prorealcode.com
//Sharing ProRealTime knowledge

// --- settings 
//per=14
//t3period=8
//b=0.7
// --- end of settings 

b2=b*b
b3=b2*b
c1=-b3
c2=(3*(b2+b3))
c3=-3*(2*b2+b+b3)
c4=(1+3*b+b3+3*b2)

n=max(1,t3period)
n=1 + 0.5*(n-1)
w1=2/(n + 1)
w2=1 - w1

//mBar=d*per

imp=0
//Level=0.0

for i=0 to per do 
 imp=imp+(open[i]-close[i])
next
imp=round(imp/pointsize)

if (imp=0 ) then 
 imp=0.0001
endif
if (imp<>0 ) then 
 imp=-imp
 DayImp=imp
endif

ddpo=DayImp
e1=w1*ddpo + w2*e1
e2=w1*e1 + w2*e2
e3=w1*e2 + w2*e3
e4=w1*e3 + w2*e4
e5=w1*e4 + w2*e5
e6=w1*e5 + w2*e6
t3=c1*e6 + c2*e5 + c3*e4 + c4*e3

once NbBar = 1
if BarIndex < NbBar+2 then
 MyDay=openday
 dayminutes = 1440*(MyDay-MyDay[1])
 MyHour=openhour
 hourminutes = 60*(MyHour-MyHour[1])
 MyMin=openminute
 barminutes = MyMin - MyMin[1] + hourminutes + dayminutes
 barminutes=abs(barminutes)
 tf = lowest[NbBar](barminutes)[1]
endif

if tf=5 then 
 N=288
elsif tf=15 then 
 N=96
elsif tf=30 then 
 N=48
elsif tf=60 then 
 N=24
else
 N=288
endif

mMax=DayImp[N-1]
mMin=DayImp[N-1]

for i = 0 to N-1 do 
if (mMax<DayImp[i]) then 
mMax=DayImp[i]
endif
if (mMin>DayImp[i]) then 
mMin=DayImp[i]
endif
next

MaxLine = mMax
MinLine = mMin

ChanLineMax=mMax/2
ChanLineMin=mMin/2

return DayImp coloured(255,0,255) style(line,2), t3 coloured(255,0,0) style(line,3), MaxLine coloured(218,165,32) style(line,3), MinLine coloured(218,165,32) style(line,3), ChanLineMax coloured(0,100,0) style(line,2), ChanLineMin coloured(0,100,0) style(line,2), 0 coloured(100,100,100) style(dottedline)