The BBands Stop indicator (Bollinger Bands Stop line) is a trend indicator. When price is over the green curve, the trend is bullish or bearish if the price is below its orange line.

It’s built with bollinger bands phases and act pretty much like a Supertrend, the BBands stop line can also be used to determiner stoploss when you jump in a trend given by its signals (drawn with big “bullets” on chart).
Bollinger bands period and deviation can be changed in settings. The “MoneyRisk” setting is a parameter to widen the spread between the bands and the current price.

This indicator has been translated from MT4 version.

//PRC_BBands Stop | indicator
//30.03.2017
//Nicolas @ www.prorealcode.com
//Sharing ProRealTime knowledge
//translated from MT4 code

// --- settings
//Length=20      // Bollinger Bands Period
//Deviation=2    // Deviation
//MoneyRisk=1.00 // Offset Factor
// --- end of settings

avg=average[Length]
dev=std[Length]*Deviation
smax = avg+dev
smin = avg-dev

if close>smax[1] then
 trend=1
endif
if close<smin[1] then
 trend=-1
endif

if trend>0 and smin<smin[1] then
 smin=smin[1]
endif
if trend<0 and smax>smax[1] then
 smax=smax[1]
endif

bsmax=smax+0.5*(MoneyRisk-1)*(smax-smin)
bsmin=smin-0.5*(MoneyRisk-1)*(smax-smin)

if(trend>0 and bsmin<bsmin[1]) then
 bsmin=bsmin[1]
endif
if(trend<0 and bsmax>bsmax[1]) then
 bsmax=bsmax[1]
endif

if trend>0 then
 TrendLine=bsmin
 r=127 
 g=255
 drawtext("•",barindex,bsmin,Dialog,Standard,10) coloured(r,g,0)
 if trend[1]<0 then
  drawtext("•",barindex,bsmin,Dialog,Standard,22) coloured(r,g,0)
 endif
endif

if trend<0 then
 TrendLine=bsmax
 r=255 
 g=165
 drawtext("•",barindex,bsmax,Dialog,Standard,10) coloured(r,g,0)
 if trend[1]>0 then
  drawtext("•",barindex,bsmax,Dialog,Standard,22) coloured(r,g,0)
 endif
endif

RETURN TrendLine coloured(r,g,0) style(line,2) as "BBands stop Trend"