Ci-dessous une demande qui a été envoyée à ProRealTime :

Bonjour

Je souhaite faire paramétrer un codage de trading auto les indicateurs pour cela sont les suivants.
– 2 moyennes mobile exponentielles 200 et 100
– un macd 9 19 6
– Bande de bollinger 20 . 2
– signal de vente ou d’achat en phase 2 haussière ou baissière bougie clôturé
– stop Loss 15 pts
– cible limite de gain 12 pts pour 0,5 contrat
– cloture totale en phase 4 de bollinger

CONDITIONS d’achats
– La moyenne mobile 100 au dessus de la 200
– les prix au dessus de la moyenne mobile 100
– Départ en phase 2 haussiere de bollinger bougie cloturé
– macd histogramme positif
– macd courbe au dessus de 0

CONDITIONS de vente
– la 100 en dessous de la 200
– les prix en dessous de la Moyenne mobile 100
– depart en phase 2 baissiere de bollinger bougie cloturé
– macd histogramme negatif
– macd courbe en dessous de 0

cdlt

PS 1 :
Pour les Bollinger, voici les 4 phases
– Phase 4 = contraction des bande
– Phase 2 = accélération des bande ouverture pour accélération
– Phase 3 = tendance
– Phase 1 = squeeze

Vous pouvez vous calquer sur bollinger % est reglé un depart haussier en depassant les 85 ou un depart baissier en depasant les 15.
Contraction retour sous les 80 pour un achat.
Contraction reour au dessus des 20 pour une vente.

PS 2 : serais t’il possible également de placer le stop loos à Break even (Prix d’entrée ) une fois les premiers 12 pts atteints ?

Et une proposition de réponse :

nbpointsforbreakeven=12

EMA100=exponentialaverage[100](close)
EMA200=exponentialaverage[200](close)
MyMACDLine=MACDline[9,19,6](close)
MyMACDHisto=MACD[12,26,9](close)
// calcul du bollinger %b
bup=BollingerUp[20](close)
bdown=BollingerDown[20](close)
bollinger=(close-bdown)/(bup-bdown)*100

// Conditions pour ouvrir une position acheteuse
c1=EMA100 > EMA200
c2=close > EMA100
c3=bollinger > 85
c4=MyMACDHisto > 0
c5=MyMACDLine > 0

IF NOT LongOnMarket AND c1 and c2 and c3 and c4 and c5 THEN
BUY 1 CONTRACTS AT MARKET
breakevenlong=0
ENDIF

If LongOnMarket and breakevenlong=0 and close > tradeprice + nbpointsforbreakeven*pointsize then
breakevenlong=1
endif
If LongOnMarket and breakevenlong=1 then
sell at tradeprice stop
endif

// Conditions pour fermer une position acheteuse
c6=bollinger crosses under 80

If LongOnMarket AND c6 THEN
SELL AT MARKET
ENDIF

// Conditions pour ouvrir une position en vente à découvert
c7=EMA100 < EMA200
c8=close < EMA100
c9=bollinger < 15
c10=MyMACDHisto < 0
c11=MyMACDLine < 0

IF NOT ShortOnMarket AND c7 and c8 and c9 and c10 and c11 THEN
SELLSHORT 1 CONTRACTS AT MARKET
breakevenshort=0
ENDIF

If ShortOnMarket and breakevenshort=0 and close < tradeprice - nbpointsforbreakeven*pointsize then
breakevenshort=1
endif
If ShortOnMarket and breakevenshort=1 then
exitshort at tradeprice stop
endif

// Conditions pour fermer une position en vente à découvert
c12=bollinger crosses over 20

IF ShortOnMarket AND c12 THEN
EXITSHORT AT MARKET
ENDIF

// Stops et objectifs : entrez vos stops et vos objectifs ici
set stop ploss 15
set target pprofit 12

PS : j’ai mis le niveau de breakeven en tant que paramètre en haut du code car vous demandiez le target et le breakeven au même niveau.