Volume indicator with a different approach, described as follow, extract from the author (Gail Mercer) description, please see PDF file of the forum topic description (link is in the code).

The difference between standard volume bars and volume bars that are at either a high or a low. If the price bar did not make a high or low then it was colored white as it contained no information. If the price bar made a high then the volume bar is blue. If the price bar made a low then the volume bar is red. If the price bar made a high and low together then I need to look at the close to determine the significance of the volume bar.
If the price bar made neither a high or low then I do not need to see it and, therefore, it is not displayed.

Downtrend Entry: Again, use the tallest volume bar during the retracement (pullback). Then look for divergence at the highs, also called low volume test.

Uptrend Entry: For an entry in an uptrend, look at the volume on each low. Remember to use the tallest volume bar on the retracement (pullback). Then look for diverging volume on the lows.

//PRC_Spec Volume | indicator
//30.11.2016
//Nicolas @ www.prorealcode.com
//Sharing ProRealTime knowledge
//converted and adapted from Metatrader4 version
//http://www.prorealcode.com/topic/volume-display-new-highlow/

if(High>High[1] and Low>=Low[1]) then  //made higher high and higher low -> high bar
 upvol = Volume
 downvol = 0
 neutralvol = 0
elsif(High>High[1] and Low<Low[1]) then //made higher high and lower low -> neutral bar or outside bar
 upvol = 0
 downvol = 0
 neutralvol = Volume
elsif(High<=High[1] and Low<Low[1]) then //made lower high and lower low -> low bar
 upvol = 0
 downvol = Volume
 neutralvol = 0
elsif(High<=High[1] and Low>=Low[1]) then //made lower high and higher low -> inside bar
 upvol = 0
 downvol = 0
 neutralvol = 0
endif

RETURN upvol coloured(0,0,255) as "up volume", downvol coloured(255,0,0) as "down volume", neutralvol coloured(128,128,128) as "neutral volume"