Bonjour à tous, pouvez vous si possible ajouter au code ci-dessous une 5 ème condition : validation SMA20
Merci par avance
Domi
// === Heikin Ashi calculation ===
once haopen=open
haclose=(open+close+high+low)/4
if barindex> 0 then
haopen=(haopen+haclose[1])/2
endif
// === Ichimoku Tenkan-sen (9 periods) ===
tenkan = (highest[9](high) + lowest[9](low)) / 2
// === Moving Average 7 ===
m7 = average[7](close)
// === Conditions ===
// 1. Bullish HA candle (validated)
haBull = haClose > haOpen
// 2. HA close above Tenkan
aboveTenkan = haClose > tenkan
// 3. M7 rising (current bar)
m7Rising = m7 > m7[1]
// 4. Bearish context: M7 was declining on previous bar
bearishCtx = m7[1] <= m7[2]
// === Screener ===
//SCREENER[haBull AND aboveTenkan AND m7Rising AND bearishCtx](m7 AS "M7", tenkan AS "Tenkan")
SCREENER[volume*close>150000 and haBull AND aboveTenkan AND m7Rising AND bearishCtx](m7 AS "M7", tenkan AS "Tenkan",Close*Volume as "Cap.")
Bonjour. Avant d’écrire quoi que ce soit, qu’entendez-vous par validation ?
Comme je l’ai dit dans mon message précédent? https://www.prorealcode.com/topic/1-er-retour-m20-impact/#post-261366
Bonjour,
Les cours au dessus de la M20 en bougie heikin ashi
Bonne journée
Domi
ok
//--------------------------------------------
// Screener: HA Bullish Reversal + Tenkan + M7 + M20
//--------------------------------------------
// === Heikin Ashi calculation ===
once haOpen = open
haClose = (open + close + high + low) / 4
IF barindex > 0 THEN
haOpen = (haOpen + haClose[1]) / 2
ENDIF
// === Ichimoku Tenkan-sen (9 periods) ===
tenkan = (highest[9](high) + lowest[9](low)) / 2
// === Moving averages ===
m7 = average[7](close)
m20 = average[20](close)
// === Conditions ===
// 1. Bullish HA candle
haBull = haClose > haOpen
// 2. HA close above Tenkan
aboveTenkan = haClose > tenkan
// 3. M7 rising (current bar)
m7Rising = m7 > m7[1]
// 4. Bearish context: M7 was declining on previous bar
bearishCtx = m7[1] <= m7[2]
// 5. M20 validation: HA close above the 20-period moving average
aboveM20 = haClose > m20
// === Screener ===
SCREENER[volume*close>150000 AND haBull AND aboveTenkan AND m7Rising AND bearishCtx AND aboveM20](m7 AS "M7", tenkan AS "Tenkan", m20 AS "M20", close*volume AS "Cap.")
