Hallo,
ich möchte trade die ich früher in Prorealtime gemacht habe auswerten.
Leider ist im Chart nur der grüne pfeil und das Viereck für den Einst ieg und den Ausstieg zu sehen.
Kann ich noch rausfinden wo der Initialstop Stopp loss gelegen hat. Kann ich die Stopp level noch irgend wo sehen oder finden?
danke euch
Sie können den Stop-Loss und den Take-Profit auf dem Diagramm mit ROTEN und BLAUEN Linien sehen.
MyLongConditions = Not OnMarket AND Close CROSSES OVER Average[20,0](close)
MyShortConditions = Not OnMarket AND Close CROSSES UNDER Average[20,0](close)
IF MyLongConditions THEN
BUY 1 CONTRACT AT MARKET
StopLoss = lowest[3](low)
TargetPrice = close + (close - StopLoss)
ELSIF MyShortConditions THEN
SELLSHORT 1 CONTRACT AT MARKET
StopLoss = highest[3](high)
TargetPrice = close - (StopLoss - close)
ENDIF
SET STOP PRICE StopLoss
SET TARGET PRICE TargetPrice
//
graphonprice TargetPrice AS "TP" coloured("Blue")
graphonprice StopLoss AS "SL" coloured("Red")
Danke für die schnelle Antwort!!!
Hallo Roberto,
kannst Du es noch so schreiben das der Take profit 2 mal so groß ist wie der stop loss also CRV 2:1
Ich habe es versucht mit
SET TARGET PRICE TargetPrice * 2 // das funktioniert aber nicht
Hallo. Sie müssen lediglich die Codezeilen 6 und 10 ändern.
TargetPrice = close + 2*(close - StopLoss)
TargetPrice = close - 2*(close - StopLoss)
Hallo und danke für die Info,
kann ich noch etwas fragen??!!
können sie bitte auch noch schreiben, das der Kurs auf Break even gezogen wird, sobald das CRV von 1:1 erreicht ist??
Los geht’s:
MyLongConditions = Not OnMarket AND Close CROSSES OVER Average[20,0](close)
MyShortConditions = Not OnMarket AND Close CROSSES UNDER Average[20,0](close)
IF MyLongConditions THEN
BUY 1 CONTRACT AT MARKET
StopLoss = lowest[3](low)
CRV11 = close + (close - StopLoss)
TargetPrice = close + 2*(close - StopLoss)
SET STOP PRICE StopLoss
SET TARGET PRICE TargetPrice
ELSIF MyShortConditions THEN
SELLSHORT 1 CONTRACT AT MARKET
StopLoss = highest[3](high)
CRV11 = close - (StopLoss - close)
TargetPrice = close - 2*(StopLoss - close)
SET STOP PRICE StopLoss
SET TARGET PRICE TargetPrice
ENDIF
//
IF (LongOnMarket AND (close >= CRV11)) OR (ShortOnMarket AND (close <= CRV11)) THEN
StopLoss = TradePrice
SET STOP PRICE StopLoss
ENDIF
//
graphonprice TargetPrice AS "TP" coloured("Blue")
graphonprice CRV11 AS "Crv 1:1" coloured("Cyan")
graphonprice StopLoss AS "SL" coloured("Red")
Danke schön, ich schau es mir Morgen an…
Ich würde den Code noch um eine Stop Regel erweitern.
Ich möchte das der Stop Loss in die Mitte zwischen Tradeprice und StopLoss gezogen wird, wenn der Kurs 70 % im Gewinn ist.
Ist dieser Code hier dafür richtig?
if longonmarket AND (close) >= (Tradeprice-StopLoss)* 1.7 Then
stopLoss = (TRADEPRICE-StopLoss)/2
SET STOP PRICE StopLoss
endif
Probieren Sie diese Version aus:
MyLongConditions = Not OnMarket AND Close CROSSES OVER Average[20,0](close)
MyShortConditions = Not OnMarket AND Close CROSSES UNDER Average[20,0](close)
IF MyLongConditions THEN
BUY 1 CONTRACT AT MARKET
StopLoss = lowest[3](low)
CRV11 = close + (close - StopLoss)
TargetPrice = close + 2*(close - StopLoss)
MyGain = abs(TargetPrice - close)
SET STOP PRICE StopLoss
SET TARGET PRICE TargetPrice
ELSIF MyShortConditions THEN
SELLSHORT 1 CONTRACT AT MARKET
StopLoss = highest[3](high)
CRV11 = close - (StopLoss - close)
TargetPrice = close - 2*(StopLoss - close)
MyGain = abs(TargetPrice - close)
SET STOP PRICE StopLoss
SET TARGET PRICE TargetPrice
ENDIF
//
IF OnMarket THEN
tempGain = PositionPrice * POSITIONPERF * PipValue * abs(CountOfPosition)
ENDIF
//
IF (LongOnMarket AND (close >= CRV11)) OR (ShortOnMarket AND (close <= CRV11)) THEN
StopLoss = TradePrice
SET STOP PRICE StopLoss
ENDIF
IF OnMarket THEN
IF tempGain >= (MyGain * 0.70) AND OnMarket THEN
IF LongOnMarket THEN
StopLoss = max(StopLoss,(close + StopLoss) / 2)
ELSIF ShortOnMarket THEN
StopLoss = min(StopLoss,(close + StopLoss) / 2)
ENDIF
SET STOP PRICE StopLoss
ENDIF
ENDIF
//
graphonprice TargetPrice AS "TP" coloured("Blue")
graphonprice CRV11 AS "Crv 1:1" coloured("Cyan")
graphonprice StopLoss AS "SL" coloured("Red")
graph PositionPerf
