THREE OUTSIDE UP-DOWN & DRAGONFLY-GRAVESTONE

Per favore NON usare i caratteri maiuscoli se non per evidenziare una parola specifica sporadicamente.

Nell’etichetta web è considerato come URLARE in una discussione, oltre ad essere visualmente meno intelligibile.

Grazie.

Si, si può fare, più tardi ti posto qualcosa.

L’ho provato su un grafico a 5 minuti (solo valute) e mi pare funzioni. Ovviamente dovrai cambiare i valori numerici per la definizione dei pattern come ti sembra più adeguato, i miei sono un pò generici:

Corpo             = abs(open - close)
OmbraSuperiore    = high - max(open,close)
OmbraInferiore    = min(open,close) - low
//Ombre           = OmbraSuperiore + OmbraInferiore
CandelaRialzista  = close > open
CandelaRibassista = close < open
BullishEngulfing  = CandelaRibassista[1] AND CandelaRialzista AND range > range[1] AND Corpo >= Corpo[1]
BearishEngulfing  = CandelaRialzista[1] AND CandelaRibassista AND range > range[1] AND Corpo >= Corpo[1]

// 1 - Three outside UP
ThreeOutsideUP    = BullishEngulfing[1] AND CandelaRialzista  AND close > close[1]  AND high > high[1]

// 2 - Three outside DOWN
ThreeOutsideDN    = BearishEngulfing[1] AND CandelaRibassista AND close < close[1] AND low < low[1]

// 3 - Gravestone doji
AmpiezzaCorpo     = 5 * pipsize              //il corpo NON deve superare questi pips
MinimoOmbraSup    = Corpo * 5                //l'ombra superiore DEVE essere almeno 5 volte il corpo
MassimoOmbraInf   = MinimoOmbraSup / 4       //l'ombra inferiore DEVE essere, al massimo, pari ad un quarto di quella superiore
Gravestone        = Corpo <= AmpiezzaCorpo AND OmbraSuperiore >= MinimoOmbraSup AND OmbraInferiore <= MassimoOmbraInf

// 4 - Dragonfly doji
AmpiezzaCorpo     = 5 * pipsize              //il corpo NON deve superare questi pips
MinimoOmbraInf    = Corpo * 5                //l'ombra inferiore DEVE essere almeno 5 volte il corpo
MassimoOmbraSup   = MinimoOmbraInf / 4       //l'ombra superiore DEVE essere, al massimo, pari ad un quarto di quella inferiore
Dragonfly         = Corpo <= AmpiezzaCorpo AND OmbraInferiore >= MinimoOmbraInf AND OmbraSuperiore <= MassimoOmbraSup

Risultato = 0
IF ThreeOutsideUP THEN
   Risultato = 1
ELSIF ThreeOutsideDN THEN
   Risultato = 2
ELSIF Gravestone THEN
   Risultato = 3
ELSIF Dragonfly THEN
   Risultato = 4
ENDIF

SCREENER [Risultato] (Risultato AS "Pattern")