Pattern candlesticks Ribassisti e Rialzisti

Indica cosa vuoi che il TS faccia quando rileva uno di questi pattern:

1 – entra subito in posizione o aspetta altri eventi?

2 – lo stop loss come lo calcola?

3 – il target profit come lo calcola?

Ecco il codice:

//                    BULLISH patterns (definition)
// https://www.investopedia.com/terms/t/three_white_soldiers.asp
// https://www.investopedia.com/terms/b/bullishengulfingpattern.asp
// https://www.investopedia.com/terms/b/bullishengulfingpattern.asp
// https://www.investopedia.com/terms/m/morningstar.asp
//
//                    BEARISH patterns (definition)
// https://www.investopedia.com/terms/e/eveningstar.asp
// https://www.investopedia.com/terms/h/hangingman.asp
// https://www.investopedia.com/terms/s/shootingstar.asp
// https://www.investopedia.com/terms/t/three_black_crows.asp
//
Bullish     = close > open
Bearish     = close < open
//Opposite  = (Bullish AND Bearish[1]) OR (Bearish AND Bullish[1])
Body        = abs(open - close)
UpperWick   = high - max(open,close)
LowerWick   = min(open,close) - low
//TotalWicks= range - Body
TallCandle  = Body >  (range * 0.50)
BigCandle   = Body >  (range * 0.75)
SmallCandle = Body <= (range * 0.50)
GapDN       = open < low[1]
//GapUP     = open > high[1]
//
//                    BULLISH patterns (setup)
MorningStar        = TallCandle[2] AND Bearish[2] AND SmallCandle[1] AND BigCandle AND Bullish
PiercingLine       = TallCandle[1] AND Bearish[1] AND GapDN AND Bullish AND TallCandle AND (close >= (low[1] + (range[1] * 0.5)))
BullishEngulfing   = Bearish[1] AND Bullish AND Body > Body[1] AND open <= close[1] AND close >= open[1] AND TallCandle
ThreeWhiteSoldiers = (summation[3](Bullish AND BigCandle) = 3) AND (summation[2](open <= close[1] AND close > high[1]) = 2)
//
//                    BEARISH patterns (setup)
EveningStar        = BigCandle[2] AND Bullish[2] AND SmallCandle[1] AND BigCandle AND Bearish
HangingMan         = SmallCandle AND (LowerWick >= (Body * 2)) AND (LowerWick > UpperWick)
ShootingStar       = SmallCandle AND (Upperwick > LowerWick)
ThreeBlackCrows    = (summation[3](Bearish AND BigCandle) = 3) AND (summation[2](open >= close[1] AND close < close[1]) = 2)
//
GoLong  = MorningStar OR PiercingLine OR BullishEngulfing OR ThreeWhiteSoldiers
GoShort = EveningStar OR HangingMan   OR ShootingStar     OR ThreeBlackCrows
//
IF Not OnMarket THEN
   IF GoLong THEN
      BUY 1 CONTRACT AT MARKET
   ELSIF GoShort THEN
      SELLSHORT 1 CONTRACT AT MARKET
   ENDIF
ENDIF

non credo lo userai così, perché entrare short perchè si è verificato un HANGING MAN credo ti prosciugherebbe il conto in poco tempo! Dovrai verificare te se il pattern identificato è in una posizione ottimale o meno.

Anche le percentuali 0.50 e 0.75 le ho messe indicativamente. Tu dovrai indicare quelle che ti sembrano più opportune.

Ho commentato alcune righe dove ci sono variabili inutilizzate, ma che ho incluso per completezza.