// -- CODE DE BASE et RAJOUT DE LA WMA4 PÉRIODES --
defparam DRAWONLASTBARONLY = true
// HORAIRES D'AFFICHAGE DES SIGNAUX
TRADINGTIME = time >= 070000 and time < 230000
// La régression quadratique est une rgéression polynomilae de degrée deux. Elle se calcule à partir de l'équation quadratique d'une parabole formée àapartir de points.
// --- VARIABLES
//length = 100
// --- FIN DES VARIABLES
y = close
x1 = barindex
x2 = square(x1)
S11 = summation[length](x2) - square(summation[length](x1))/length
S12 = summation[length](x1*x2) - (summation[length](x1) * summation[length](x2))/length
S22 = summation[length](square(x2)) - square(summation[length](x2))/length
Sy1 = summation[length](y*x1) - (summation[length](y)*summation[length](x1))/length
Sy2 = summation[length](y*x2) - (summation[length](y)*summation[length](x2))/length
max1 = average[length](x1)
max2 = average[length](x2)
may = average[length](y)
b2 = ((Sy1 * S22) - (Sy2*S12))/(S22*S11 - square(S12))
b3 = ((Sy2 * S11) - (Sy1 * S12))/(S22 * S11 - square(S12))
b1 = may - b2*max1 - b3*max2
QR = b1 + b2*x1 + b3*x2 // Résultat de la moyenne quadratique
// Calcul de la médiane du Canal de Donchian
// P = 10 // nombre de périodes
HAUT = highest[prd](high[1])
BAS = lowest[prd](low[1])
MEDIAN = (HAUT + BAS) / 2 // Calcul de la Médiane du Canal de Donchian
// Utiliser l'indicateur de " CANAL DONCHIAN - Candle_Median " et appliquer median et chandelier sur le graphique
// VARIABLES GÉNÉRALES
EMA7 = ExponentialAverage[7](close)
ST = supertrend[2.5,10]
RSI14 = rsi[14]
WMA4 = WeightedAverage[4](close) // Correspond à la ligne Court Terme de PRTBands
// FIN DES VARIABLES
// ------------------------------------------------------------
// CRÉATION DU SIGNAL D'ACHAT
if EMA7 < CLOSE and close > ST and close > WMA4 and RSI14 > 50 and close > MEDIAN and QR < close and TRADINGTIME THEN
DRAWARROWUP (barindex,low-6.0 * pointsize)coloured(0,0,255) // BLEU
endif
// ------------------------------------------------------------
// CRÉATION DU SIGNAL DE VENTE
if close < EMA7 AND CLOSE < ST and close < WMA4 and RSI14 < 50 and close < MEDIAN and QR > close and TRADINGTIME THEN
DRAWARROWDOWN (barindex,high+6.0 * pointsize)coloured(255,0,0) // ROUGE
endif
RETURN