conversion indicateur tradingview a prorealtime

Bon tard, voici le code pour prorealtime. Merci de vous assurer de partager le code au format correct (pincer le bouton Insérer le code).

//--------------------------------------------------------------//
//PRC_Method Signals
//version = 0
//14.05.24
//Iván González @ www.prorealcode.com
//Sharing ProRealTime knowledge
//-------------------------------------------------------------//
//----Inputs------------------------------------------//
leftbars=2
rightbars=2
//----------------------------------------------------//
//-----Pivot High&Low---------------------------------//
src1 = low
src2 = high
/////pivots low
if src1 > src1[rightbars] and lowest[rightbars](src1) > src1[rightbars] and src1[rightbars] < lowest[leftbars](src1)[rightbars+1] then
$pivotlowy[z+1] = src1[rightbars]
$pivotlowx[z+1] = barindex[rightbars]
z=z+1
endif
/////pivots high
if src2 < src2[rightbars] and highest[rightbars](src2)<src2[rightbars] and src2[rightbars]>highest[leftbars](src2)[rightbars+1] then
$pivothighy[t+1]=src2[rightbars]
$pivothighx[t+1]=barindex[rightbars]
t=t+1
endif
//----------------------------------------------------//
swh=$pivothighy[t]
swl=$pivotlowy[z]

once hprice=0
if t<>t[1] then
hprice=swh
else
hprice=hprice[1]
endif

once le=0
if t<>t[1] then
le=1
else
if le[1] and high>hprice then
le=0
else
le=le[1]
endif
endif

once lprice=0
if z<>z[1] then
lprice=swl
else
lprice=lprice[1]
endif
once se=0
if z<>z[1] then
se=1
else
if se[1] and low<lprice then
se=0
else
se=se[1]
endif
endif

sefiltered=se and not le
lefiltered=le and not se

once prev=0
if sefiltered then
prev=1
elsif lefiltered then
prev=-1
else
prev=prev[1]
endif

sefinal=sefiltered and prev[1]=-1
lefinal=lefiltered and prev[1]=1

if sefinal then
drawtext("▲",barindex,low)coloured("blue")
elsif lefinal then
drawtext("▼",barindex,high)coloured("red")
endif
//----------------------------------------------------//
return