crolakstrading wrote:

I can not change the time 7 pm to 1am

Just an observation … the only times you have in your code are Lines 10 and 11 (4:15am and 7:15am) is this correct?

I think you need some code in there to define that 070000 is the previous day.

Just as a trial, see if below works logically?

Hi,

You use an “IntraDay” time frame (15 min) and “intraday” times run from 00:00:00 (reset IntraDayBarIndex) to 23:59:59… so, all the times you use in your code are related to the current (intra)day …

Hi.. As @GraHal mentions original code ‘s start and end time on same day however you want start and end on different days. Another thing is that the Higher high/low values are reset when intradaybarindex resets which I think is 23:00:00, so range between HH and LL wouldn’t be over the whole time window either. HH and LL now reset at start of time window and flags ensure endtime not valid till start time reached. Try this,  compare it with other, on a time setting that work in both and see if levels are the same. druby    

DefParam DrawOnLastBarOnly = true

// --- property settings

//AlphaText = 180 // [integer] Transparency text 0-255
//Offset    = 10  // [integer] Offset AlphaTextnumeric/rectangle OPR
//Level     = 1   // [boolean] (0=hidden; 1=observable)
//Text      = 1   // [boolean  (0=no text; 1=text)
//AlphaRect = 30  // [integer] Transparency Rectangle 0-255
// --- end



starttime = 190000
endtime   = 010000
 
AlphaText = abs(max(min(AlphaText,255) ,-255)) // Restricted input variable Max-Min
AlphaRect = abs(max(min(AlphaRect,255) ,-255))
//------------------------------------------------------ open data window
if time = starttime and startFlag = 0   then
startFlag = 1
startBar = barindex
hh = 0
ll = 0
endFlag = 0
endif

//------------------------------------------------------ update hh/ll while in window open
if startFlag = 1 then
if high > hh then
hh = high
endif
if low < ll or ll = 0 then
ll = low
endif
endif

//------------------------------------------------------ close data window
if time = endTime and startFlag = 1 and endFlag = 0 then
endFlag = 1
endBar = barindex
startFlag = 0
elsif startFlag = 1 then
endbar = barindex
endif

//------------------------------------------------------ when window closed
if endFlag = 1 then
dif = hh-ll
fib38 = hh
fib0  = ll
endif


if islastbarupdate then

DrawRectangle(startbar,hh,endbar,ll) coloured(0,255,255,AlphaRect)bordercolor(0,0,0,0) // Option Rectangle (AlphaText = transparence)
//DrawEllipse(startbar,hh,endbar,ll) coloured(0,255,255,alpha)   // Option ellipse
//DrawSegment(startbar,Hh,endbar,Hh) coloured(123,123,123,alpha)      // Segment Upper
//DrawSegment(startbar,Ll,endbar,Ll) coloured(123,123,123,alpha)      // Segment Lower
//DrawSegment(startbar,hh,endbar-12,ll) coloured(123,123,123,alpha)   // Segment Left
//DrawSegment(startbar+12,Hh,endbar,Ll) coloured(123,123,123,alpha)   // Segment Right

if startFlag = 0  and endFlag = 1 then
if Text = 1 then
DrawText("OPR #dif#pts",startbar+6,hh+(offset*4),SansSerif,Bold,11) coloured(150,150,150,AlphaText)
DrawText(" HI  #hh# ",startbar+6,hh+3,SansSerif,Standard,10) coloured(22,111,0,AlphaText)

//DrawText("Bull Market",startbar+5,hh+(offset),Dialog,Bold,12) coloured(22,111,0,AlphaText) // Option text only
//DrawLine(barindex-1,hh,barindex,hh) coloured(111,11,111,AlphaText) // Option ligne continue
DrawSegment(endbar,hh,barindex,hh) coloured(0,200,0,AlphaText)
DrawText("╔═════► ",startbar+6,hh+(dif),Dialog,Bold,10) coloured(22,111,0,AlphaText) // Option OPR - 100% (Glyphe alt+201, alt+205)
DrawText(" LO  #ll# ",startbar+6,ll-2,SansSerif,Standard,10) coloured(200,20,20,AlphaText)

//DrawText("Bear Market",startbar+5,ll-(offset),Dialog,Bold,12) coloured(200,20,20,AlphaText) // Option text only
//DrawLine(barindex-1,ll,barindex,ll) coloured(111,11,111,AlphaText) // Option ligne continue
DrawSegment(endbar,ll,barindex,ll) coloured(200,0,0,AlphaText)
DrawText("╚═════► ",startbar+6,ll-(dif),Dialog,Bold,10) coloured(200,10,10,AlphaText) // Option OPR - 100% (Glyphe alt+200, alt+205)
endif // text

if Level = 1 then
fibobull100 = (fib38-fib0)*3.0050+fib38
DrawSegment(endbar+2,fibobull100,barindex-10,fibobull100) coloured(200,10,10,AlphaText)
DrawText("300% SL",barindex-3,fibobull100,SansSerif,Bold,11) coloured(200,10,10,AlphaText)

fibobull162 = (fib38-fib0)*3+fib0
DrawSegment(endbar+2,fibobull162,barindex-10,fibobull162) coloured(25,100,0,AlphaText)
DrawText("200% E2",barindex-3,fibobull162,SansSerif,Bold,11) coloured(25,100,0,AlphaText)

fibobull62 = (fib38-fib0)*2.5+fib0
DrawSegment(endbar+2,fibobull62,barindex-10,fibobull62) coloured(25,100,0,AlphaText)
DrawText("150% E1",barindex-3,fibobull62,SansSerif,Bold,11) coloured(25,100,0,AlphaText)
fibobull62 = (fib38-fib0)*2+fib0

DrawSegment(endbar+2,fibobull62,barindex-10,fibobull62) coloured(105,105,105,AlphaText)
DrawText("100%",barindex-3,fibobull62,SansSerif,Bold,11) coloured(105,105,105,AlphaText)



fibobear62 = (fib0-fib38)*3.0050+fib0
DrawSegment(endbar+2,fibobear62,barindex-10,fibobear62) coloured(200,11,11,AlphaText)
DrawText("300% SL",barindex-3,fibobear62,SansSerif,Bold,11) coloured(200,10,10,AlphaText)

fibobear100 = (fib0-fib38)*2+fib0
DrawText("200% E2",barindex-3,fibobear100,SansSerif,Bold,11) coloured(25,100,0,AlphaText)
DrawSegment(endbar+2,fibobear100,barindex-10,fibobear100) coloured(25,100,0,AlphaText)

fibobear124 = (fib0-fib38)*1.5+fib0
DrawSegment(endbar+2,fibobear124,barindex-10,fibobear124) coloured(25,100,0,AlphaText)
DrawText("150% E1",barindex-3,fibobear124,SansSerif,Bold,11) coloured(25,100,0,AlphaText)

fibobear162 = (fib0-fib38)*1+fib0
DrawSegment(endbar+2,fibobear162,barindex-10,fibobear162) coloured(105,105,105,AlphaText)
DrawText("100%",barindex-3,fibobear162,SansSerif,Bold,11) coloured(105,105,105,AlphaText)

endif // level 1
endif // startFlag ...
endif // islastbarupdate
return

Try this, I did a back test run it on DAX 15min seems to do something  

DEFPARAM CumulateOrders = False
starttime = 191500
endtime   = 011500
trigTime  = 100000 // added!
 
//------------------------------------------------------ open data window
if time = starttime and startFlag = 0   then
startFlag = 1
startBar = barindex
hh = 0
ll = 0
endFlag = 0
trigFlag = 0
endif

//------------------------------------------------------ update hh/ll while in window open
if startFlag = 1 then
if high > hh then
hh = high
endif
if low < ll or ll = 0 then
ll = low
endif
endif

//------------------------------------------------------ close data window
if time = endTime and startFlag = 1 and endFlag = 0 then
endFlag = 1
endBar = barindex
startFlag = 0
elsif startFlag = 1 then
endbar = barindex
endif

//------------------------------------------------------ when window closed
if endFlag = 1 then
dif = hh-ll
fib38 = hh
fib0  = ll
endif
//------------------------------------------------------ when trigger time reached
if time >= trigTime and startFlag = 0 and endFlag = 1 then     // added! +2 lines
trigFlag = 1
endif
  
EntryPrice = (fib38-fib0)*2.5+fib0
EntryPrice1 = (fib0-fib38)*1.5+fib0
StopLoss = (fib38-fib0)*3.0050+fib38
StopLoss1 = (fib0-fib38)*3.0050+fib0
takeprofit = (fib38-fib0)/2+fib0     //changed
takeprofit1 = (fib0-fib38)/2+fib0    //changed!


// Conditions to enter Short positions
IF NOT ShortOnMarket AND startFlag = 0  and endFlag = 1 and trigFlag = 0 then  // changed!
SEllSHORT 1 CONTRACTS AT EntryPrice LIMIT
ENDIF
IF OnMarket THEN
SET STOP LOSS StopLoss
Endif
Set Target pProfit takeprofit

// Conditions to enter long positions
//IF NOT LongOnMarket AND >tradingtime< and >value2< THEN                        //????? was this line in error  --- 

If NOT LongOnMarket AND startFlag = 0 and endFlag = 1 and trigFlag = 0 then  // changed and added!
BUY 1 CONTRACTS AT EntryPrice1 LIMIT
ENDIF
IF OnMarket THEN
SET STOP LOSS StopLoss1
ENDIF
Set Target pProfit takeprofit1

On win11, IG, I used  snipping tool to crop an image of desktop area. Alternate, you can use the share feature from the top right hand side of Detailed report, ‘Save’ saves an image. Below, in the reply section, Attachments [Select File] click!, then navigate to the location of the required image file, select  file and then click ‘open’. Image should be previewed in attachment section.. One other thing, Attachment only show up when viewing  AND your logged in . At times you get automatically logged out. IF use several devices maybe that one has logged out.

I’m not 100% on this but, on lines 58 and 69 we have ‘IF ON MARKET THEN’ where, line 58 set the short stoploss and line 69 the long stoploss. So when long limit order triggered, line 66, and order executed, (on market) the stoploss and target are set. Now since on the market, the next run through of the code sees the line 58 ‘IF ON MARKET THEN ‘ again and reset the stoploss to the short stoploss. Since both targets are the same level the change doesn’t affect those. However, in a long trade the stop level is set below the price, and if price goes below it, the stop is triggered, but when it’s now changed to above the price, effectively the price is below the short stoploss level and triggers, out of market. So if this is what’s happening then the lines need to be changed to: 58    IF SHORT ON MARKET THEN 69    IF LONG ON MARKET THEN This would remove this conflict.   On another point,  if a position only exits if the stop or target met, and every day a new stop and target are calculated, then depending on price movement the new stop and targets would be the active ones. So if in a position, it appears possible for these moving stops and targets and price movements, to make a target bigger than was originally set, and opposite for the stoploss, making it worse than originally set. This all if trade triggered before the 10am cut off point, but trade could last, lets say days, and who knows were stop and target will be on that day. If that’s not your intension then the logic around the stop and target need some thought. This is if, i’m seeing this all right! Regards