ATR % Múltiple

Viewing 2 posts - 1 through 2 (of 2 total)

Author

Posts

10/18/2024 at 4:29 PM #239216 quote

Participant

Junior

Podrían ayudarme en la creación del código para este indicador?

Se trataría de aplicar la idea que aparece en la página https://www.tradingview.com/script/oimVgV7e-ATR-multiple-from-50-MA/

Queremos establecer un umbral basado en el múltiplo del rango verdadero promedio (ATR%) del promedio móvil simple (SMA) de 50 días para comenzar a tomar ganancias cuando las posiciones superan entre 7 y 10 veces el ATR% del SMA de 50 días.

La fórmula empleada es la siguiente:

A = ATR% = $ ATR / $ Último precio realizado
B = % de ganancia de la media móvil de 50 días

B / A = % de ATR múltiplo de la media móvil de 50 días

Gracias

10/24/2024 at 2:18 PM #239419 quote

Iván González

Moderator

Legend

Buenas,
Aquí tienes el indicador que realiza el cálculo.

//---------------------------------------------//
//PRC_ATR% multiple from MovingAverage
//version = 0
//24.10.2024
//Iván González @ www.prorealcode.com
//Sharing ProRealTime knowledge
//---------------------------------------------//
//---------------Inputs------------------------//
//---------------------------------------------//
matype=0
maLength=50
multipleAtr=10
//---------------------------------------------//
//-------------Moving average------------------//
//---------------------------------------------//
ma=average[maLength,matype](close)
//---------------------------------------------//
//-------------Average True Range--------------//
//---------------------------------------------//
atr=averagetruerange[14](close)
//---------------------------------------------//
//-------% Gain From Moving Average------------//
//---------------------------------------------//
gainFromMA=round((close/ma-1)*100,2)
//---------------------------------------------//
//-------% ATR---------------------------------//
//---------------------------------------------//
pctATR=round(atr/close*100,2)
//---------------------------------------------//
//------ATR % Multiple from Moving Average-----//
//---------------------------------------------//
atrMultFromMA=round(gainFromMA/pctATR,2)
//---------------------------------------------//
//-----------Multiple ATR Detection------------//
//---------------------------------------------//
if atrMultFromMA>=multipleAtr then
drawpoint(barindex,high+atr,3)coloured("fuchsia")
endif
//---------------------------------------------//
//-------------Data last candle----------------//
//---------------------------------------------//
if islastbarupdate then
drawtext("% Gain From MA = #gainFromMA#",-200,100)anchor(bottomright,xshift,yshift)
drawtext("ATR% = #pctATR#",-200,75)anchor(bottomright,xshift,yshift)
drawtext("ATR% Multiple from MA = #atrMultFromMA#",-200,125)anchor(bottomright,xshift,yshift)
endif

return ma as "Moving Average" coloured("blue")