Volatility Scalper S1 V01

Hi,

I tried to make a strategy based on Volatility Scalper Indicator of Nicolas. As a reminder, this indicator detects the high volatility of market places. It’s the reflect when the market is making big move on the same bar.

This strategy is based on this indicator.

• When the value of the upside volume is considered as good, value > treshold and close > long MM, ->  buy position is taken.
• When the value of the downside volume is considered as good, value > treshold and close < long MM, ->  sell position is taken.
• Stop according to traling stop
• time 1530 – 2200, everyday
• option / reversal position size (possibility to activate or not)
• option for buy, sell or both

all suggestions are open…

• maybe specify more precise time ranges according to the volatility of DJI, same thing for different days… ?
• others ?
• …
• others.. ?

//VOLATILITY SCALPER STRATEGY
//@MAKSIDE - 2020
//V0.1

// Définition des paramètres du code
DEFPARAM CumulateOrders = False // Cumul des positions désactivé

//$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$ Volatility Scalper
//@Nicolas/PRT
// Variables
threshATRPeriod = 40
smoothing = 2
verticalShiftPercent = 0
// --

threshATRPeriod = max(1, threshATRPeriod)
smoothing = max(1, smoothing)

diff = averagetruerange[1] - averagetruerange[2]
if(close-close[1])>0 THEN
upsidevol = averagetruerange[1] + diff * 0.5
upsideVol = max(upsideVol, 0)
downsidevol = 0
ELSE
upsidevol = 0
downsidevol = averagetruerange[1] + diff * 0.5
downsideVol = max(downsideVol, 0)
ENDIF

t = DEMA[smoothing](AverageTrueRange[threshATRPeriod])
t = t + (t*(verticalShiftPercent/100))
//$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$

//PARAMETERS OF STRATEGY **************************************
//level of volatility indicator / bull market
Cupsidevol = 10
//level of volatility indicator / bear market
CdownsideVol = 20
//buy conditions
Cdatetimebuy = (CurrentTime > 153000) and currenttime < 220000
//sell conditions
Cdatetimesell = (CurrentTime > 153000) and currenttime < 220000
Cbuy = upsidevol>Cupsidevol and upsidevol > t and Cdatetimebuy
Csell = downsidevol>CdownsideVol and downsidevol > t and Cdatetimesell

// Strategy - 1 : buy, 2 : sell, 3 : both
Cchoice = 2

//Reverse martingale 1 : ON, 0 : OFF
levier = 1
n = 1

reversemartingale = 0
//$$$$$$$$$$$$$$ REVERSE MARTINGALE
// in case of loss, back to initial value 1
// in case of winning, increase by one unit
// in case of 4 consecutive wins, back to initial value 1

if reversemartingale = 1 then
ONCE n = levier
IF Strategyprofit<Strategyprofit[1] THEN
n = levier
ENDIF
IF Strategyprofit>Strategyprofit[1] THEN
n = n + levier
ENDIF
IF n >= 6 * levier THEN // modifier la valeur selon vos préférences
n = levier
ENDIF
endif

//STRATEGY **************************************

//
if Cchoice = 1 or 3 then
if close > Average[4800](close) then

IF not longonmarket and Cbuy THEN
BUY n CONTRACT AT MARKET
ENDIF

SET STOP pLOSS 5

endif
endif

if Cchoice = 2 or 3 then
if close < Average[4800](close) then

IF not shortonmarket and Csell THEN
sellshort n CONTRACT AT MARKET
ENDIF

SET STOP pLOSS 5
endif
endif

//TRAILING STOP **************************************

trailingstart = 15 //trailing will start @trailinstart points profit
trailingstep = 5 //trailing step to move the "stoploss"

//reset the stoploss value
IF NOT ONMARKET THEN
newSL=0
ENDIF

//manage long positions
IF LONGONMARKET THEN
//first move (breakeven)
IF newSL=0 AND close-tradeprice(1)>=trailingstart*pipsize THEN
newSL = tradeprice(1)+trailingstep*pipsize
ENDIF
//next moves
IF newSL>0 AND close-newSL>=trailingstep*pipsize THEN
newSL = newSL+trailingstep*pipsize
ENDIF
ENDIF

//manage short positions
IF SHORTONMARKET THEN
//first move (breakeven)
IF newSL=0 AND tradeprice(1)-close>=trailingstart*pipsize THEN
newSL = tradeprice(1)-trailingstep*pipsize
ENDIF
//next moves
IF newSL>0 AND newSL-close>=trailingstep*pipsize THEN
newSL = newSL-trailingstep*pipsize
ENDIF
ENDIF

//stop order to exit the positions
IF newSL>0 THEN
SELL AT newSL STOP
EXITSHORT AT newSL STOP
ENDIF
//************************************************************************

Volatility_scalper_1S_v01.png