On request I programmed the Thomas Demark indicator TD Sequential -Setup. It counts up to 9 consecutive bars to complete the setup and if the setup is completed with a “perfection buy /sell signal” it draws an arrow over/below the signal candle.

The TD Setup requires 9 consecutive bars matching criteria plus a final criterium to generate a buy/sell signal. After A TD Setup is completed the TD countdown starts which requires 13 occurrences of a pattern that don’t have to be consecutive. On completion this generates additional buy/sell signals (blue arrows).

The TD Sequential Indicator was developed by Tom DeMark for trading on the FOREX market. It is also suitable for the market of commodities and options.
This indicator looks for the opposite trend in order to anticipate and identify the turning points of the market. It provides signals in intraday and also on daily timeframe.

Discussions about this indicator can be found in this forum topic: https://www.prorealcode.com/topic/td-sequential-setup/

once TDSL=0
once TDSS=0
once BuySetup=0
once SellSetup=0
Once BuyCountdown=0
once SellCountdown=0
if close[1]>close[5] and close<close[4] then
 bearishflip=1
 bullishflip=0
elsif close[1]<close[5] and close>close[4] then
 bullishflip=1
 bearishflip=0
endif
if close<close[4] and bearishflip then
 TDSL=TDSL+1
 TDSS=0
elsif close>close[4] and bullishflip then
 TDSS=TDSS+1
 TDSL=0
endif
if TDSL>0 and TDSL<10 then
 drawtext("#TDSL#",barindex,low-10*pipsize) coloured(0,255,0)
endif
if TDSL=9 then
 L=(low<low[3] and low<low[2]) or (low[1]<low[2] and low[1]<low[3])
 bearishflip=0
 TDSL=0
 BuySetup=1
 if L then
  DRAWARROWUP(barindex,low-20*pipsize) coloured(0,255,0)
 endif
endif
if TDSS>0 and TDSS<10 then
 drawtext("#TDSS#",barindex,high+10*pipsize) coloured(255,0,0)
endif
if TDSS=9 then
 S=(high>high[2] and high>high[3]) or (high[1]>high[3] and high[1]>high[2])
 bullishflip=0
 TDSS=0
 SellSetup=1
 if S then
  DRAWARROWDOWN(barindex,high+20*pipsize) coloured(255,0,0)
 endif
endif
if BuySetup then
 if close<=low[2] then
  BuyCountdown=BuyCountdown+1
  drawtext("#BuyCountdown#",barindex,low-10*pipsize) coloured(0,0,255)
 endif
 if BuyCountdown=8 then
  Bar8=barindex
 elsif BuyCountdown=13 then     // TD Countdown perfection buy
  if low<=close[barindex-Bar8] then
   DRAWARROWUP(barindex,low-20*pipsize) coloured(0,0,255)
  endif
  BuySetup=0
  BuyCountdown=0
 endif
elsif SellSetup then
 if close>=high[2] then
  SellCountdown=SellCountdown+1
  drawtext("#SellCountdown#",barindex,high+10*pipsize) coloured(0,0,255)
 endif
 if SellCountdown=8 then
  Bar8=barindex
 elsif SellCountdown=13 then  //TD Countdown perfection sell
  if high>=close[barindex-Bar8] then
   DRAWARROWDOWN(barindex,high+20*pipsize) coloured(0,0,255)
  endif
  SellSetup=0
  SellCountdown=0
 endif
endif
return