This indicator finds and displays the potential bullish and bearish turning points using different parameters:

LONG SIGNALS
1. Red/Green candle (reversal)
2. Bullish candle close above the open of the previous red candle
3. Space to the left (the low of the last 3 candles lower than the low of the last 50 candles)
4. default stochastic (8,3,3) was in the oversold area within the last 3 candles

SHORT SIGNALS
1. Green/Red candle (reversal)
2. Bearish candle close below the close of the previous green candle
3. Space to the left (the high of the last 3 candles higher than the high of the last 50 candles)
4. default stochastic (8,3,3) was in the overbought area within the last 3 candles

Indicator coded by a request in the English forum.

//PRC_Reversal point indicator | indicator
//09.04.2017
//Nicolas @ www.prorealcode.com
//Sharing ProRealTime knowledge
//https://www.prorealcode.com/topic/need-help-coding-the-following-reversal-indicator/

// LONG
//Red/Green candle (reversal)
//Bullish candle close above the open of the previous red candle
//Space to the left (the low of the last 3 candles lower than the low of the last 50 candles)
//default stochastic (8,3,3) was in the oversold area within the last 3 candles

sto = stochastic[8,3]

c1 = close[1]<open[1] and close>open
c2 = close>open[1]
c3 = lowest[3](low)<lowest[50](low)[1] or lowest[3](low)<lowest[50](low)[2] or lowest[3](low)<lowest[50](low)[3]
c4 = summation[3](sto<20)>0
long = c1 and c2 and c3 and c4

if long then
 drawarrowup(barindex,lowest[3](low)) coloured(0,255,0)
endif

// SHORT
//Green/Red candle (reversal)
//Bearish candle close below the close of the previous green candle
//Space to the left (the high of the last 3 candles higher than the high of the last 50 candles)
//default stochastic (8,3,3) was in the overbought area within the last 3 candles.

c5 = close[1]>open[1] and close<open
c6 = close<open[1]
c7 = highest[3](high)>highest[50](high)[1] or highest[3](high)>highest[50](high)[2] or highest[3](high)>highest[50](high)[3]
c8 = summation[3](sto>80)>0
short = c5 and c6 and c7 and c8

if short then
 drawarrowdown(barindex,highest[3](high)) coloured(255,0,0)
endif

return long as "long reversal", short as "short reversal"