MACD Reloaded

Inspired by existing MACDs on PRC or TW, this indicator is a “Reloaded” evolution of the MACD in which all parameters are adjustable.

The indicator is shared with the settings that seem to perform best, but which can be extensively modified.

Have fun!

EMAshort1 = Average[short1,mmshort1](close)
EMAshort2 = Average[short2,mmshort2](EMAshort1)
DifferenceShort = EMAshort1 - EMAshort2
ReloadedShort = EMAshort1 + DifferenceShort

EMAlong1 = Average[long1,mmlong1](close)
EMAlong2 = Average[long2,mmlong2](EMAlong1)
DifferenceLong = EMAlong1 - EMAlong2
ReloadedLong = EMAlong1 + DifferenceLong

ReloadedMACD = ReloadedShort - ReloadedLong

signal1=ExponentialAverage[signal](RELOADEDMACD)
signal2=ExponentialAverage[signal](signal1)
DIFFERENCE2=signal1-signal2

SignalMACD=signal1+DIFFERENCE2

if signalMACD>=ReloadedMACD then
r=255
g=69
b=0
else
r=54
g=224
b=208
endif

DRAWCANDLE(signalMACD,reloadedMACD,signalMACD,reloadedMACD) coloured(r,g,b)

if reloadedMACD crosses over signalMACD or reloadedMACD crosses under signalMACD then
drawtext("●",barindex,signalMACD,Dialog,Bold,12) coloured(r,g,b)
endif


RETURN ReloadedMACD coloured(54,224,208) style(dottedline,1 ) as "Reloaded MACD", SignalMACD coloured(255,69,0) style(line,2) as "Signal MACD", 0 coloured(100,100,100) as "zero line"