// This Pine Script™ code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © vnhilton

//@version=5
indicator("ZigZag With ATR Filter [vnhilton]", "ZigZag w/ ATR Filter", true, max_lines_count = 500, max_labels_count = 500)

//Parameters
errorMsgToggle           = input.bool (true, "Show Pivot Point Length Error Message")
showPivotValueText       = input.bool (true, "",                            inline = "Pivot Label")
showTrendText            = input.bool (true, "Show Pivot Value/Trend Text", inline = "Pivot Label")

showZigZagSizeText       = input.bool (true, "",                                    inline = "ZigZag Settings")
showZigZagLengthText     = input.bool (true, "",                                    inline = "ZigZag Settings")
showZigZagVolumeText     = input.bool (true, "Show ZigZag Size/Length/Volume Text", inline = "ZigZag Settings")

atrLength                = input.int  (20,   "ATR/Pivot Point Period",           1,                                                                                                                                                                                    inline = "Lengths")
pivotLength              = input.int  (3,    "",                                 3, 501, 2,   "Pivot point length must be an odd number; Looks for middle bar of period to be highest/lowest, with preceding and succeeding lower/higher and lower/higher highs/lows", inline = "Lengths")
atrMultiplier            = input.float(2,    "ATR Multiplier Minimum Threshold", 0, tooltip = "A pivot is only recognised if it is at least N ATRs away from the prior pivot")
maxLines                 = input.int  (497,  "Show the last N ZigZag lines",            2, 497)

pivotLabelSize           = input.string("Normal",            "Label Size",                 ["Auto", "Tiny", "Small", "Normal", "Large", "Huge"],                                                                                                                                                                                                                                                                                             group = "Pivot Label Settings")
highPivotStyle           = input.string("Label Lower Right", "High/Low Pivot Label Style", ["None", "X-Cross", "Cross", "Triangle Up", "Triangle Down", "Flag", "Circle", "Arrow Up", "Arrow Down", "Label Up", "Label Down", "Label Left", "Label Right", "Label Lower Left", "Label Lower Right", "Label Upper Left", "Label Upper Right", "Label Center", "Label Square", "Label Diamond", "Label Text Outline"], inline = "Label Style", group = "Pivot Label Settings")
lowPivotStyle            = input.string("Label Upper Right", "",                           ["None", "X-Cross", "Cross", "Triangle Up", "Triangle Down", "Flag", "Circle", "Arrow Up", "Arrow Down", "Label Up", "Label Down", "Label Left", "Label Right", "Label Lower Left", "Label Lower Right", "Label Upper Left", "Label Upper Right", "Label Center", "Label Square", "Label Diamond", "Label Text Outline"], inline = "Label Style", group = "Pivot Label Settings")

confHighPivotLabelColorU = input.color(color.new(color.green,   80), "High Pivot Confirmed Colors", inline = "P High Confirmed", group = "Label Uptrend/Downtrend/Range Color Settings")
confHighPivotLabelColorD = input.color(color.new(color.red,     80), "",                            inline = "P High Confirmed", group = "Label Uptrend/Downtrend/Range Color Settings")                                       
confHighPivotLabelColorR = input.color(color.new(color.gray,    80), "",                            inline = "P High Confirmed", group = "Label Uptrend/Downtrend/Range Color Settings")
liveHighPivotLabelColorU = input.color(color.new(color.blue,    80), "High Pivot Live Colors",      inline = "P High Live",      group = "Label Uptrend/Downtrend/Range Color Settings")
liveHighPivotLabelColorD = input.color(color.new(color.fuchsia, 80), "",                            inline = "P High Live",      group = "Label Uptrend/Downtrend/Range Color Settings")
liveHighPivotLabelColorR = input.color(color.new(color.yellow,  80), "",                            inline = "P High Live",      group = "Label Uptrend/Downtrend/Range Color Settings")
confLowPivotLabelColorU  = input.color(color.new(color.green,   80), "Low Pivot Confirmed Colors",  inline = "P Low Confirmed",  group = "Label Uptrend/Downtrend/Range Color Settings")
confLowPivotLabelColorD  = input.color(color.new(color.red,     80), "",                            inline = "P Low Confirmed",  group = "Label Uptrend/Downtrend/Range Color Settings")
confLowPivotLabelColorR  = input.color(color.new(color.gray,    80), "",                            inline = "P Low Confirmed",  group = "Label Uptrend/Downtrend/Range Color Settings")
liveLowPivotLabelColorU  = input.color(color.new(color.blue,    80), "Low Pivot Live Colors",       inline = "P Low Live",       group = "Label Uptrend/Downtrend/Range Color Settings")
liveLowPivotLabelColorD  = input.color(color.new(color.fuchsia, 80), "",                            inline = "P Low Live",       group = "Label Uptrend/Downtrend/Range Color Settings")
liveLowPivotLabelColorR  = input.color(color.new(color.yellow,  80), "",                            inline = "P Low Live",       group = "Label Uptrend/Downtrend/Range Color Settings")

confHighPivotTextColorU  = input.color(color.green,   "High Text Confirmed Colors", inline = "T High Confirmed", group = "Text Uptrend/Downtrend/Range Color Settings")
confHighPivotTextColorD  = input.color(color.red,     "",                           inline = "T High Confirmed", group = "Text Uptrend/Downtrend/Range Color Settings")                                       
confHighPivotTextColorR  = input.color(color.gray,    "",                           inline = "T High Confirmed", group = "Text Uptrend/Downtrend/Range Color Settings")
liveHighPivotTextColorU  = input.color(color.blue,    "High Text Live Colors",      inline = "T High Live",      group = "Text Uptrend/Downtrend/Range Color Settings")
liveHighPivotTextColorD  = input.color(color.fuchsia, "",                           inline = "T High Live",      group = "Text Uptrend/Downtrend/Range Color Settings")
liveHighPivotTextColorR  = input.color(color.yellow,  "",                           inline = "T High Live",      group = "Text Uptrend/Downtrend/Range Color Settings")
confLowPivotTextColorU   = input.color(color.green,   "Low Text Confirmed Colors",  inline = "T Low Confirmed",  group = "Text Uptrend/Downtrend/Range Color Settings")
confLowPivotTextColorD   = input.color(color.red,     "",                           inline = "T Low Confirmed",  group = "Text Uptrend/Downtrend/Range Color Settings")
confLowPivotTextColorR   = input.color(color.gray,    "",                           inline = "T Low Confirmed",  group = "Text Uptrend/Downtrend/Range Color Settings")
liveLowPivotTextColorU   = input.color(color.blue,    "Low Text Live Colors",       inline = "T Low Live",       group = "Text Uptrend/Downtrend/Range Color Settings")
liveLowPivotTextColorD   = input.color(color.fuchsia, "",                           inline = "T Low Live",       group = "Text Uptrend/Downtrend/Range Color Settings")
liveLowPivotTextColorR   = input.color(color.yellow,  "",                           inline = "T Low Live",       group = "Text Uptrend/Downtrend/Range Color Settings")

confZZLineColorU         = input.color (color.green, "Uptrend/Downtrend/Range Colors",                 inline = "Confirmed Colors", group = "Confirmed ZigZag Line Settings")
confZZLineColorD         = input.color (color.red,   "",                                               inline = "Confirmed Colors", group = "Confirmed ZigZag Line Settings")
confZZLineColorR         = input.color (color.gray,  "",                                               inline = "Confirmed Colors", group = "Confirmed ZigZag Line Settings")
confZZLineWidth          = input.int   (2,             "Line Width/Style", 1,                            inline = "Confirmed WS",     group = "Confirmed ZigZag Line Settings")
confZZLineStyle          = input.string("Solid",       "", ["Arrow Right", "Dashed", "Dotted", "Solid"], inline = "Confirmed WS",     group = "Confirmed ZigZag Line Settings")

liveZZLineColorU         = input.color (color.blue,    "Uptrend/Downtrend/Range Colors",                 inline = "Live Colors", group = "Live ZigZag Line Settings")
liveZZLineColorD         = input.color (color.fuchsia, "",                                               inline = "Live Colors", group = "Live ZigZag Line Settings")
liveZZLineColorR         = input.color (color.yellow,  "",                                               inline = "Live Colors", group = "Live ZigZag Line Settings")
liveZZLineWidth          = input.int   (2,               "Line Width/Style", 1,                            inline = "Live WS",     group = "Live ZigZag Line Settings")
liveZZLineStyle          = input.string("Solid",         "", ["Arrow Right", "Dashed", "Dotted", "Solid"], inline = "Live WS",     group = "Live ZigZag Line Settings")

livePZZLineColorU        = input.color (color.new(color.green, 80), "Up/Down/Level Colors",                           inline = "Potential Colors", group = "Potential ZigZag Line Settings")
livePZZLineColorD        = input.color (color.new(color.red,   80), "",                                               inline = "Potential Colors", group = "Potential ZigZag Line Settings")
livePZZLineColorR        = input.color (color.new(color.gray,  80), "",                                               inline = "Potential Colors", group = "Potential ZigZag Line Settings")
livePZZLineWidth         = input.int   (2,                            "Line Width/Style", 1,                            inline = "Potential WS",     group = "Potential ZigZag Line Settings")
livePZZLineStyle         = input.string("Solid",                      "", ["Arrow Right", "Dashed", "Dotted", "Solid"], inline = "Potential WS",     group = "Potential ZigZag Line Settings")

livePZZLabelColorU       = input.color(color.new(color.green, 80), "Up/Down Label Colors", inline = "Potential L Colors", group = "Potential ZigZag Label Settings")
livePZZLabelColorD       = input.color(color.new(color.red,   80), "",                     inline = "Potential L Colors", group = "Potential ZigZag Label Settings")
livePZZTextColorU        = input.color(color.new(color.green, 80), "Up/Down Text Colors",  inline = "Potential T Colors", group = "Potential ZigZag Label Settings")
livePZZTextColorD        = input.color(color.new(color.red,   80), "",                     inline = "Potential T Colors", group = "Potential ZigZag Label Settings")
//Arrays
var int    [] pivotIndices = array.new<int>()
var float  [] pivotValues  = array.new<float>()
var string [] pivotTypes   = array.new<string>()
var string [] pivotTrends  = array.new<string>()
var label  [] pivotLabels  = array.new<label>()
var line   [] zigZagLines  = array.new<line>()

//Potential line and label
var line potentialLine = na
var label potentialLabel = na

//Label text function
LabelText(arrayIndex, pivotIndex, value, trend) =>
    string finalText = na

    if showPivotValueText
        finalText += str.tostring(value, format.mintick)   

    if showTrendText
        if showPivotValueText 
            finalText += " "

        finalText += "(" + trend + ")" 

    if arrayIndex > 0
        lastPivotIndex = array.get(pivotIndices, arrayIndex - 1)

        if showZigZagSizeText 
            if showPivotValueText or showTrendText
                finalText += "\nS: "
            else
                finalText += "S: "
            finalText += str.tostring(math.abs(value - array.get(pivotValues, arrayIndex - 1)), format.mintick)

        if showZigZagLengthText     
            if showPivotValueText or showTrendText or showZigZagSizeText
                finalText += "\nL: "
            else
                finalText += "L: "
            finalText += str.tostring(pivotIndex - lastPivotIndex + 1)

        if showZigZagVolumeText
            cuVol = 0.0
            for i = pivotIndex to lastPivotIndex
                cuVol += volume[bar_index - i] // Poor solution as it won't work if leftmost pivot of last leg > 500 bars away

            if showPivotValueText or showTrendText or showZigZagSizeText or showZigZagLengthText
                finalText += "\nV: "
            else
                finalText += "V: "                
            finalText += str.tostring(cuVol, format.volume)

    finalText 

//Label type function
LabelType(choice) =>
    switch
        choice == "None"               => label.style_none
        choice == "X-Cross"            => label.style_xcross
        choice == "Cross"              => label.style_cross
        choice == "Triangle Up"        => label.style_triangleup
        choice == "Triangle Down"      => label.style_triangledown
        choice == "Flag"               => label.style_flag
        choice == "Circle"             => label.style_circle
        choice == "Arrow Up"           => label.style_arrowup
        choice == "Arrow Down"         => label.style_arrowdown
        choice == "Label Up"           => label.style_label_up
        choice == "Label Down"         => label.style_label_down
        choice == "Label Left"         => label.style_label_left
        choice == "Label Right"        => label.style_label_right
        choice == "Label Lower Left"   => label.style_label_lower_left
        choice == "Label Lower Right"  => label.style_label_lower_right
        choice == "Label Upper Left"   => label.style_label_upper_left
        choice == "Label Upper Right"  => label.style_label_upper_right
        choice == "Label Center"       => label.style_label_center
        choice == "Label Square"       => label.style_square
        choice == "Label Diamond"      => label.style_diamond
        =>                                label.style_text_outline

//Label size function
LabelSizing() =>
    switch pivotLabelSize
        "Auto"   => size.auto
        "Tiny"   => size.tiny
        "Small"  => size.small
        "Normal" => size.normal
        "Large"  => size.large
        =>          size.huge

//Line style function
LineStyling(choice) =>
    switch 
        choice == "Arrow Right" => line.style_arrow_right
        choice == "Dashed"      => line.style_dashed
        choice == "Dotted"      => line.style_dotted
        =>                         line.style_solid

//Trend determinator function
GetTrend(pivot, value) =>

    //If it is one of the first 2 pivots ever
    if array.size(pivotIndices) < 3
        if pivot == "high"
            "H"
        else
            "L"

    //If the new pivot can be compared to an existing last pivot of the same type
    else
        if value      >  array.get(pivotValues, array.size(pivotValues) - 3)
            if pivot == "high"
                "HH"
            else
                "HL"

        else if value == array.get(pivotValues, array.size(pivotValues) - 3) //Else if statement to prevent later codes from running if prior codes executed, as function doesn't end once a value is returned
            if pivot == "high"
                "EH"
            else
                "EL"

        else
            if pivot == "high"
                "LH"
            else
                "LL"
       
//Trend colors function
TrendColors(pivot, index) =>

    currTrend = array.get(pivotTrends, index)
    prevTrend = index != 0 ? array.get(pivotTrends, index - 1) : na

    //Uptrend colours
    if ((prevTrend == "L" or prevTrend == "EL" or prevTrend == "HL") and currTrend == "HH") or (prevTrend == "HH" and currTrend == "HL")
        if pivot == "High"
            [confHighPivotLabelColorU, liveHighPivotLabelColorU, confHighPivotTextColorU, liveHighPivotTextColorU, confZZLineColorU, liveZZLineColorU]
        else
            [confLowPivotLabelColorU,  liveLowPivotLabelColorU,  confLowPivotTextColorU,  liveLowPivotTextColorU,  confZZLineColorU, liveZZLineColorU]

    //Downtrend colours
    else if ((prevTrend == "H" or prevTrend == "EH" or prevTrend == "LH") and currTrend == "LL") or (prevTrend == "LL" and currTrend == "LH")

        if pivot == "High"
            [confHighPivotLabelColorD, liveHighPivotLabelColorD, confHighPivotTextColorD, liveHighPivotTextColorD, confZZLineColorD, liveZZLineColorD]
        else
            [confLowPivotLabelColorD,  liveLowPivotLabelColorD,  confLowPivotTextColorD,  liveLowPivotTextColorD,  confZZLineColorD, liveZZLineColorD]

    //Range colors
    else 
        if pivot == "High"
            [confHighPivotLabelColorR, liveHighPivotLabelColorR, confHighPivotTextColorR, liveHighPivotTextColorR, confZZLineColorR, liveZZLineColorR]
        else
            [confLowPivotLabelColorR,  liveLowPivotLabelColorR,  confLowPivotTextColorR,  liveLowPivotTextColorR,  confZZLineColorR, liveZZLineColorR]

//Store pivot function
StorePivot(pivot) =>

    //Garbage logic
    if array.size(zigZagLines) == maxLines
        label.delete(array.first(pivotLabels))
        line.delete (array.first(zigZagLines))

        removedIndex = array.shift(pivotIndices)
        removedValue = array.shift(pivotValues)
        removedType  = array.shift(pivotTypes)
        removedTrend = array.shift(pivotTrends)
        removedLabel = array.shift(pivotLabels)
        removedLine  = array.shift(zigZagLines)

    //Store data
    array.push(pivotIndices, bar_index - ((pivotLength - 1) / 2))
    array.push(pivotValues,  pivot == "high" ? high[(pivotLength - 1) / 2] : low[(pivotLength - 1) / 2])
    array.push(pivotTypes,   pivot == "high" ? "High" : "Low")
    array.push(pivotLabels,  label.new(na, na, style = pivot == "high" ? LabelType(highPivotStyle) : LabelType(lowPivotStyle), size = LabelSizing()))
    culVol = 0.0
    rightSideVol = 0.0
    for i = 0 to (pivotLength - 1) / 2
        culVol += volume[i]
        if i != (pivotLength - 1) / 2
            rightSideVol += volume[i]

    if array.size(pivotLabels) > 1
        array.push(zigZagLines,  line.new (na, na, na, na))

    //Get trend
    pivotTrend = GetTrend(pivot, array.last(pivotValues))
    array.push(pivotTrends,  pivotTrend)

//Update pivot function
UpdatePivot(pivot) =>

    //Update data
    array.set(pivotIndices, array.size(pivotIndices) - 1, bar_index - ((pivotLength - 1) / 2))
    array.set(pivotValues,  array.size(pivotValues)  - 1, pivot == "high" ? high[(pivotLength - 1) / 2] : low[(pivotLength - 1) / 2])
    
    pivotTrend = GetTrend(pivot, array.last(pivotValues))
    array.set(pivotTrends,  array.size(pivotTrends)  - 1, pivotTrend)

//Error message
noError = true

table error = table.new(position.top_right, 1, 1, bgcolor=color.red)

if pivotLength % 2 != 1 // If pivot point length is an even number
    if errorMsgToggle
        table.cell(error, 0, 0, "ERROR: Please input an odd number pivot point period", text_color = color.white)
    noError := false

if bar_index < pivotLength - 1 //If total bars on chart is less than pivot bar length
    if errorMsgToggle
        table.cell(error, 0, 0, "ERROR: Not enough bars on the chart. Please lower pivot point period", text_color = color.white)
    noError := false

//Volatilty filter
atr = ta.atr(atrLength)

//1) CHECK FOR PIVOTS
if noError

    //Check variables
    noHighPivot = false
    noLowPivot  = false

    //Looking for at least 1 instance where a pivot cannot be created
    for i = pivotLength - 1 to 1                  

        //Left side bar
        if i >  (pivotLength - 1) / 2            
            if high[i] > high[i - 1]           
                noHighPivot := true

            if low[i]  <  low[i - 1]           
                noLowPivot  := true

        //Middle and right side bar
        if i <= (pivotLength - 1) / 2            
            if high[i] < high[i - 1]            
                noHighPivot := true
            
            if low[i]  >  low[i - 1]           
                noLowPivot  := true

    //2) STORE OR UPDATE PIVOTS

    //Update variable
    updateLast = false

    //If if will be the 2nd+ pivot
    if array.size(pivotIndices) != 0 

        //If the last pivot was a high pivot
        if array.last(pivotTypes) == "High"

            //If the new pivot will also be a high pivot, and is higher than the last pivot
            if not noHighPivot and high[(pivotLength - 1) / 2] > array.last(pivotValues)
                UpdatePivot("high")
                updateLast := true

            //If the new pivot will be a low pivot, and volatility filter can be applied and distance from last pivot satisfies said filter, and the pivot isn't on the same bar as the last pivot, and the pivot is lower than the last pivot
            if not noLowPivot  and not na(atr[(pivotLength - 1) / 2]) and math.abs(low [(pivotLength - 1) / 2] - array.last(pivotValues))  >= atr[(pivotLength - 1) / 2] * atrMultiplier and bar_index - ((pivotLength - 1) / 2) != array.last(pivotIndices) and low [(pivotLength - 1) / 2] < array.last(pivotValues)
                StorePivot("low")

        //If the last pivot was a low pivot
        else

            //If the new pivot will also be a low pivot, and is lower than the last pivot
            if not noLowPivot  and low [(pivotLength - 1) / 2] < array.last(pivotValues)
                UpdatePivot("low")
                updateLast := true

            //If the new pivot will be a high pivot, and volatility filter can be applied and distance from last pivot satisfies said filter, and the pivot isn't on the same bar as the last pivot, and the pivot is higher than the last pivot
            if not noHighPivot and not na(atr[(pivotLength - 1) / 2]) and math.abs(high[(pivotLength - 1) / 2] - array.last(pivotValues)) >= atr[(pivotLength - 1) / 2] * atrMultiplier and bar_index - ((pivotLength - 1) / 2) != array.last(pivotIndices) and high[(pivotLength - 1) / 2] > array.last(pivotValues)
                StorePivot("high")

    //If it will be the first pivot
    else
        if not noHighPivot
            StorePivot("high")

        if not noLowPivot
            StorePivot("low")

    //3) PLOT PIVOTS
    if array.size(pivotLabels) > 0
        for i = 0 to array.size(pivotLabels) - 1

            //If the pivot has not been plotted yet or the last pivot needs updating
            if na(label.get_x(array.get(pivotLabels, i))) or (i == array.size(pivotLabels) - 1 and updateLast)
                
                //Get trend colors
                [confPivotLabelColor,  livePivotLabelColor,  confPivotTextColor,  livePivotTextColor,  confZZLineColor, liveZZLineColor] = TrendColors(array.get(pivotTypes, i), i)

                //Plot labels
                label.set_x        (array.get(pivotLabels, i),           array.get(pivotIndices, i))
                label.set_y        (array.get(pivotLabels, i),           array.get(pivotValues,  i))
                label.set_text     (array.get(pivotLabels, i), LabelText(i, array.get(pivotIndices, i), array.get(pivotValues,  i), array.get(pivotTrends, i)))
                label.set_color    (array.get(pivotLabels, i), barstate.isconfirmed ? confPivotLabelColor : livePivotLabelColor)
                label.set_textcolor(array.get(pivotLabels, i), barstate.isconfirmed ? confPivotTextColor  : livePivotTextColor)

                //If there are 2+ pivots
                if i != 0
                    
                    //Plot lines
                    line.set_xy1  (array.get(zigZagLines, i - 1), array.get(pivotIndices, i - 1), array.get(pivotValues, i - 1))
                    line.set_xy2  (array.get(zigZagLines, i - 1), array.get(pivotIndices, i)    , array.get(pivotValues, i))
                    line.set_color(array.get(zigZagLines, i - 1), barstate.isconfirmed ? confZZLineColor : liveZZLineColor)
                    line.set_style(array.get(zigZagLines, i - 1), barstate.isconfirmed ? LineStyling(confZZLineStyle) : LineStyling(liveZZLineStyle))
                    line.set_width(array.get(zigZagLines, i - 1), barstate.isconfirmed ? confZZLineWidth              : liveZZLineWidth)

        //Create potential line and label
        if na(potentialLine)
            potentialLine  := line.new(na, na, na, na, style = LineStyling(livePZZLineStyle), width = livePZZLineWidth)
            potentialLabel := label.new(na, na, size = LabelSizing())

        //Plot potential line and label
        if array.last(pivotIndices) == bar_index - ((pivotLength - 1) / 2)
            line.set_xy1(potentialLine, na, na)
            line.set_xy2(potentialLine, na, na)
            label.set_xy(potentialLabel, na, na)

        else
            if close > array.last(pivotValues)
                if array.last(pivotTypes) == "High" and array.size(pivotLabels) > 1
                    line.set_xy1(potentialLine, array.get(pivotIndices, array.size(pivotIndices) - 2), array.get(pivotValues, array.size(pivotValues) - 2))
                else
                    line.set_xy1(potentialLine, array.last(pivotIndices), array.last(pivotValues))

                line.set_xy2  (potentialLine, bar_index, high)
                line.set_color(potentialLine, livePZZLineColorU)

                label.set_xy(potentialLabel, bar_index, high)
                label.set_text(potentialLabel, LabelText(array.last(pivotTypes) == "High" and array.size(pivotLabels) > 1 ? array.size(pivotLabels) - 1 : array.size(pivotLabels), bar_index, high, GetTrend("high", high)))
                label.set_color(potentialLabel, livePZZLabelColorU)
                label.set_style(potentialLabel, LabelType(highPivotStyle))
                label.set_textcolor(potentialLabel, livePZZTextColorU)

            else if close == array.last(pivotValues)
                line.set_xy1  (potentialLine, array.last(pivotIndices), array.last(pivotValues))
                line.set_xy2  (potentialLine, bar_index,                close)
                line.set_color(potentialLine, livePZZLineColorR)

                label.set_xy(potentialLabel, na, na)

            else
                if array.last(pivotTypes) == "Low"  and array.size(pivotLabels) > 1
                    line.set_xy1(potentialLine, array.get(pivotIndices, array.size(pivotIndices) - 2), array.get(pivotValues, array.size(pivotValues) - 2))
                else
                    line.set_xy1(potentialLine, array.last(pivotIndices), array.last(pivotValues))

                line.set_xy2  (potentialLine, bar_index, low)
                line.set_color(potentialLine, livePZZLineColorD)

                label.set_xy(potentialLabel, bar_index, low)
                label.set_text(potentialLabel, LabelText(array.last(pivotTypes) == "Low" and array.size(pivotLabels) > 1 ? array.size(pivotLabels) - 1 : array.size(pivotLabels), bar_index, low, GetTrend("low", low)))
                label.set_color(potentialLabel, livePZZLabelColorD)
                label.set_style(potentialLabel, LabelType(lowPivotStyle))
                label.set_textcolor(potentialLabel, livePZZTextColorD)